mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
91 lines
4.5 KiB
Bash
91 lines
4.5 KiB
Bash
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Maintainer: Bruno Pagani <archange@archlinux.org>
|
|
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
|
|
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
|
|
# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
|
|
# Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - replace make/optdepends on python{,2}-cairocffi with python{,2}-cairo (cffi has haskell dep)
|
|
# - disable lto via setup.cfg
|
|
|
|
pkgname=python-matplotlib
|
|
pkgver=3.5.1
|
|
pkgrel=1
|
|
pkgdesc="A python plotting library, making publication quality plots"
|
|
arch=(x86_64)
|
|
url="https://matplotlib.org"
|
|
license=(custom)
|
|
depends=(freetype2 python-cycler python-dateutil python-fonttools python-kiwisolver python-numpy
|
|
python-packaging python-pillow python-pyparsing qhull)
|
|
optdepends=('tk: Tk{Agg,Cairo} backends'
|
|
'pyside2: alternative for Qt5{Agg,Cairo} backends'
|
|
'pyside6: alternative for Qt6{Agg,Cairo} backends'
|
|
'python-pyqt5: Qt5{Agg,Cairo} backends'
|
|
'python-pyqt6: Qt6{Agg,Cairo} backends'
|
|
'python-gobject: for GTK{3,4}{Agg,Cairo} backend'
|
|
'python-wxpython: WX{Agg,Cairo} backend'
|
|
'python-cairo: {GTK{3,4},Qt{5,6},Tk,WX}Cairo backends'
|
|
'python-tornado: WebAgg backend'
|
|
'ffmpeg: for saving movies'
|
|
'imagemagick: for saving animated gifs'
|
|
'ghostscript: usetex dependencies'
|
|
'texlive-bin: usetex dependencies'
|
|
'texlive-latexextra: usetex usage with pdflatex'
|
|
'python-certifi: https support')
|
|
makedepends=(git python-setuptools-scm-git-archive python-certifi)
|
|
checkdepends=(python-pytest python-pytest-xdist python-pytest-runner python-pytest-rerunfailures xorg-server-xvfb
|
|
texlive-bin texlive-core texlive-latexextra texlive-pictures ghostscript inkscape ffmpeg imagemagick
|
|
gtk4 python-cairo python-gobject python-pyqt5 pyside2 python-pyqt6 pyside6 python-tornado python-wxpython tk
|
|
jupyter-nbconvert jupyter-nbformat python-ipykernel python-pandas python-pikepdf python-pytz)
|
|
_tag=312c1fb08c5d46aaccaf8b62c8673e4202523e8a # git rev-parse v${pkgver}
|
|
_ftver=2.11.0
|
|
source=(git+https://github.com/matplotlib/matplotlib.git#tag=${_tag}?signed
|
|
https://github.com/QuLogic/mpl-images/archive/v3.5.0-with-freetype-${_ftver}/mpl-images-3.5.0-ft${_ftver}.tar.gz
|
|
freetype.patch)
|
|
b2sums=('SKIP'
|
|
'fed606dcd4d338c6b1c7dd2add58b42b0e819598129618289036dda0499584287315819cce647c35999eb8375875e0488ca20311b03c79cf76dddb2bbdf366ba'
|
|
'514324b3e17e832d5199eaa6592c05ca662b1164ddc95f16ea076d6a1063b06e6a8fa4eac7740e5f73afbcc9d17244c5cc41373d5787f62cd58eab10249302c9')
|
|
validpgpkeys=(23CAB59E3332F94D26BEF0378D86E7FAE5EB0C10) # Elliott Sales de Andrade <quantum.analyst@gmail.com>
|
|
|
|
prepare() {
|
|
cd matplotlib
|
|
# Fix SCM detected version
|
|
rm -r .git
|
|
echo "Version: ${pkgver}" > PKG-INFO
|
|
# Use system freetype and qhull, disable LTO
|
|
sed -e 's|#system_freetype = False|system_freetype = True|' -e 's|#system_qhull = False|system_qhull = True|' -e 's|#enable_lto = True|enable_lto = False|' mplsetup.cfg.template > mplsetup.cfg
|
|
patch -p1 < ../freetype.patch # From Fedora/upstream
|
|
# Install tests for check()
|
|
sed -i 's|#tests = False|tests = True|' mplsetup.cfg
|
|
# Use appropriate baseline images for tests
|
|
rm ../mpl-images-3.5.0-with-freetype-${_ftver}/matplotlib/test_streamplot/streamplot_startpoints.*
|
|
for _module in matplotlib mpl_toolkits
|
|
do
|
|
cp -r ../mpl-images-3.5.0-with-freetype-${_ftver}/${_module}/* lib/${_module}/tests/baseline_images/
|
|
done
|
|
}
|
|
|
|
build() {
|
|
cd matplotlib
|
|
python setup.py build
|
|
}
|
|
|
|
check() {
|
|
cd matplotlib
|
|
python -m venv --system-site-packages test-env
|
|
test-env/bin/python setup.py install --skip-build
|
|
# test_ipynb: https://github.com/matplotlib/matplotlib/issues/21654
|
|
# test_pcolornearestunits: https://github.com/matplotlib/matplotlib/issues/21271
|
|
xvfb-run -a -s "-screen 0 640x480x24" \
|
|
test-env/bin/python -m pytest -ra -n auto -v --color=yes --pyargs matplotlib mpl_toolkits.tests -k 'not test_ipynb and not test_pcolornearestunits'
|
|
}
|
|
|
|
package() {
|
|
cd matplotlib
|
|
python setup.py install --root "${pkgdir}" --prefix=/usr --optimize=1 --skip-build
|
|
install -Dm644 doc/users/project/license.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}/
|
|
# Remove tests
|
|
rm -r "${pkgdir}"$(python -c "import site; print(site.getsitepackages()[0])")/{matplotlib,mpl_toolkits}/tests/
|
|
}
|