mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-28 22:57:37 +00:00
87 lines
2.8 KiB
Bash
87 lines
2.8 KiB
Bash
# $Id$
|
|
# Maintainer: Ray Rashif <schiv@archlinux.org>
|
|
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove intel-tbb depend for v5 and v6
|
|
# - remove -DCPU_BASELINE_{ENABLE,DISABLE} flags for SSE
|
|
|
|
pkgbase=opencv
|
|
pkgname=(opencv opencv-samples)
|
|
pkgver=3.4.3
|
|
pkgrel=1
|
|
pkgdesc="Open Source Computer Vision Library"
|
|
arch=(x86_64)
|
|
license=(BSD)
|
|
url="http://opencv.org/"
|
|
depends=(openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 jasper)
|
|
depends_armv7h=('intel-tbb')
|
|
depends_aarch64=('intel-tbb')
|
|
makedepends=(cmake python-numpy python2-numpy mesa eigen hdf5 lapacke gtk3)
|
|
optdepends=('opencv-samples: samples'
|
|
'gtk3: for the HighGUI module'
|
|
'hdf5: support for HDF5 format'
|
|
'opencl-icd-loader: For coding with OpenCL'
|
|
'python-numpy: Python 3 interface'
|
|
'python2-numpy: Python 2 interface')
|
|
source=("$pkgbase-$pkgver.tar.gz::https://github.com/opencv/opencv/archive/$pkgver.zip"
|
|
"opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz")
|
|
sha256sums=('37c7d8c3b9807902ad11b9181bbde61dcb3898a78a563130494752f46fe8cc5f'
|
|
'6dfb51326f3dfeb659128df952edecd45683626a965aa4a8e1e9c970c40fb636')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
# cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
|
|
cmake ../$pkgname-$pkgver \
|
|
-DWITH_OPENCL=ON \
|
|
-DWITH_OPENGL=ON \
|
|
-DWITH_TBB=ON \
|
|
-DOpenGL_GL_PREFERENCE=GLVND \
|
|
-DBUILD_WITH_DEBUG_INFO=OFF \
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_PERF_TESTS=OFF \
|
|
-DBUILD_EXAMPLES=ON \
|
|
-DINSTALL_C_EXAMPLES=ON \
|
|
-DINSTALL_PYTHON_EXAMPLES=ON \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_INSTALL_LIBDIR=lib \
|
|
-DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
|
|
-DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
|
|
-DLAPACK_CBLAS_H="/usr/include/cblas.h" \
|
|
-DLAPACK_LAPACKE_H="/usr/include/lapacke.h"
|
|
make
|
|
}
|
|
|
|
package_opencv() {
|
|
options=(staticlibs)
|
|
|
|
cd build
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
# install license file
|
|
install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
|
|
cd "$pkgdir"/usr/share
|
|
|
|
# separate samples package
|
|
mv OpenCV/samples "$srcdir/$pkgname-samples"
|
|
mv OpenCV $pkgname # otherwise folder naming is inconsistent
|
|
}
|
|
|
|
package_opencv-samples() {
|
|
pkgdesc+=" (samples)"
|
|
depends=("opencv=$pkgver")
|
|
unset optdepends
|
|
|
|
mkdir -p "$pkgdir"/usr/share/opencv
|
|
cp -r "$srcdir"/opencv-samples "$pkgdir"/usr/share/opencv/samples
|
|
# fix permissions
|
|
chmod 755 "$pkgdir"/usr/share/opencv/samples/*
|
|
|
|
# install license file
|
|
install -Dm644 "$srcdir"/opencv-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
}
|