mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-28 22:57:37 +00:00
277 lines
11 KiB
Bash
277 lines
11 KiB
Bash
# Maintainer: Laurent Carlier <lordheavym@gmail.com>
|
||
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
||
# Contributor: Jan de Groot <jgc@archlinux.org>
|
||
# Contributor: Andreas Radke <andyrtr@archlinux.org>
|
||
# Contributor: Dan Johansen <strit@manjaro.org>
|
||
|
||
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
# - Removed Gallium3D drivers/packages for chipsets that don't exist in our ARM devices (intel, VMware svga).
|
||
# - added broadcom and panfrost vulkan packages
|
||
# - enable lto for aarch64
|
||
|
||
highmem=1
|
||
|
||
pkgbase=mesa
|
||
pkgname=('vulkan-mesa-layers' 'opencl-mesa' 'vulkan-radeon' 'vulkan-swrast' 'vulkan-virtio' 'vulkan-broadcom' 'vulkan-panfrost' 'libva-mesa-driver' 'mesa-vdpau' 'mesa')
|
||
pkgdesc="An open-source implementation of the OpenGL specification"
|
||
pkgver=23.0.1
|
||
pkgrel=2
|
||
arch=('x86_64')
|
||
makedepends=('python-mako' 'libxml2' 'libx11' 'xorgproto' 'libdrm' 'libxshmfence' 'libxxf86vm'
|
||
'libxdamage' 'libvdpau' 'libva' 'wayland' 'wayland-protocols' 'zstd' 'elfutils' 'llvm'
|
||
'libomxil-bellagio' 'libclc' 'clang' 'libglvnd' 'libunwind' 'lm_sensors' 'libxrandr'
|
||
'systemd' 'valgrind' 'glslang' 'vulkan-icd-loader' 'directx-headers' 'cmake' 'meson')
|
||
makedepends+=('rust' 'rust-bindgen' 'spirv-tools' 'spirv-llvm-translator') # rusticl dependencies
|
||
url="https://www.mesa3d.org/"
|
||
license=('custom')
|
||
source=(https://mesa.freedesktop.org/archive/mesa-${pkgver}.tar.xz{,.sig}
|
||
0001-iris-Retry-DRM_IOCTL_I915_GEM_EXECBUFFER2-on-ENOMEM.patch
|
||
0002-Revert-iris-Avoid-abort-if-kernel-can-t-allocate-mem.patch
|
||
0003-intel-fs-fix-scheduling-of-HALT-instructions.patch
|
||
LICENSE)
|
||
sha256sums=('e8e586856b55893abae9bdcdb98b41c081d909bb1faf372e6e7262307bf34adf'
|
||
'SKIP'
|
||
'99264c77d63d6fa810e295914808cde9f580a64e913e99fa794c1aa25a4f8fb2'
|
||
'd6ef8fb1809e8aeae0ec32bfe916adb770c64880bfd3d0f4472a616c9f356a9a'
|
||
'dc6790b5be0e80c23e74ae18ca1a2b40f57f4211cc7b645bf22b63af3b790e40'
|
||
'7052ba73bb07ea78873a2431ee4e828f4e72bda7d176d07f770fa48373dec537')
|
||
b2sums=('50d358e393037381d0d848f868ac3439b0851809c3533432dc428bd77e81bc71bbfd2b598e221b6e8c4c2528ef32e5624aec4fe2e552e01ee98abbcf96a1f5b7'
|
||
'SKIP'
|
||
'a90bfc47fb3a46eff1ef2455c7aa18c2bb515ec217b423d0a87cc5f3b824a77c0381e1378498464418644108142022dcd3c289e157877c6ae7584beaec1d9987'
|
||
'bd52994305fc0fa2f12c46ea3208bbb24f97495d9bad73120d83a6cdcf7e48f5ff0d14ac0055765516b70caacdf024fca4159b70b054e85f2783c78c9218aefe'
|
||
'37d1d070c45c85bce8abe3524a3f8d9ac9ed6326a3eec653cd89fffce3630b08eb9b96b11aeb495488230449c99f9b508f73a15e53265d2b159286b0e2dda7cc'
|
||
'1ecf007b82260710a7bf5048f47dd5d600c168824c02c595af654632326536a6527fbe0738670ee7b921dd85a70425108e0f471ba85a8e1ca47d294ad74b4adb')
|
||
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D' # Emil Velikov <emil.l.velikov@gmail.com>
|
||
'946D09B5E4C9845E63075FF1D961C596A7203456' # Andres Gomez <tanty@igalia.com>
|
||
'E3E8F480C52ADD73B278EE78E1ECBE07D7D70895' # Juan Antonio Suárez Romero (Igalia, S.L.) <jasuarez@igalia.com>
|
||
'A5CC9FEC93F2F837CB044912336909B6B25FADFA' # Juan A. Suarez Romero <jasuarez@igalia.com>
|
||
'71C4B75620BC75708B4BDB254C95FAAB3EB073EC' # Dylan Baker <dylan@pnwbakers.com>
|
||
'57551DE15B968F6341C248F68D8E31AFC32428A6') # Eric Engestrom <eric@engestrom.ch>
|
||
|
||
prepare() {
|
||
cd mesa-$pkgver
|
||
|
||
# https://gitlab.freedesktop.org/drm/intel/-/issues/6851
|
||
# https://gitlab.freedesktop.org/mesa/mesa/-/merge_requests/20449
|
||
patch -Np1 -i ../0001-iris-Retry-DRM_IOCTL_I915_GEM_EXECBUFFER2-on-ENOMEM.patch
|
||
patch -Np1 -i ../0002-Revert-iris-Avoid-abort-if-kernel-can-t-allocate-mem.patch
|
||
|
||
# https://gitlab.freedesktop.org/mesa/mesa/-/issues/7110
|
||
# https://gitlab.freedesktop.org/mesa/mesa/-/merge_requests/20765
|
||
patch -Np1 -i ../0003-intel-fs-fix-scheduling-of-HALT-instructions.patch
|
||
}
|
||
|
||
build() {
|
||
case "${CARCH}" in
|
||
armv7h) GALLIUM=",etnaviv,kmsro,lima,panfrost,tegra,v3d,vc4" ;;
|
||
aarch64) GALLIUM=",etnaviv,kmsro,lima,panfrost,svga,v3d,vc4" ;;
|
||
esac
|
||
|
||
# Build only minimal debug info to reduce size
|
||
CFLAGS+=' -g1'
|
||
CXXFLAGS+=' -g1'
|
||
|
||
arch-meson mesa-$pkgver build \
|
||
-D b_ndebug=true \
|
||
-D b_lto=$([[ $CARCH == aarch64 ]] && echo true || echo false) \
|
||
-D platforms=x11,wayland \
|
||
-D gallium-drivers=r300,r600,radeonsi,freedreno,nouveau,swrast,virgl,zink,d3d12${GALLIUM} \
|
||
-D vulkan-drivers=amd,swrast,broadcom,panfrost,virtio-experimental \
|
||
-D vulkan-layers=device-select,overlay \
|
||
-D dri3=enabled \
|
||
-D egl=enabled \
|
||
-D gallium-extra-hud=true \
|
||
-D gallium-nine=true \
|
||
-D gallium-rusticl=true \
|
||
-D rust_std=2021 \
|
||
-D gallium-omx=bellagio \
|
||
-D gallium-opencl=icd \
|
||
-D gallium-va=enabled \
|
||
-D gallium-vdpau=enabled \
|
||
-D gallium-xa=disabled \
|
||
-D gbm=enabled \
|
||
-D gles1=disabled \
|
||
-D gles2=enabled \
|
||
-D glvnd=true \
|
||
-D glx=dri \
|
||
-D libunwind=disabled \
|
||
-D llvm=enabled \
|
||
-D lmsensors=enabled \
|
||
-D osmesa=true \
|
||
-D shared-glapi=enabled \
|
||
-D microsoft-clc=disabled \
|
||
-D video-codecs=vc1dec,h264dec,h264enc,h265dec,h265enc \
|
||
-D valgrind=enabled
|
||
|
||
# Print config
|
||
meson configure build
|
||
|
||
ninja -C build
|
||
meson compile -C build
|
||
|
||
# fake installation to be seperated into packages
|
||
# outside of fakeroot but mesa doesn't need to chown/mod
|
||
DESTDIR="${srcdir}/fakeinstall" meson install -C build
|
||
}
|
||
|
||
_install() {
|
||
local src f dir
|
||
for src; do
|
||
f="${src#fakeinstall/}"
|
||
dir="${pkgdir}/${f%/*}"
|
||
install -m755 -d "${dir}"
|
||
mv -v "${src}" "${dir}/"
|
||
done
|
||
}
|
||
|
||
package_vulkan-mesa-layers() {
|
||
pkgdesc="Mesa's Vulkan layers"
|
||
depends=('libdrm' 'libxcb' 'wayland' 'python')
|
||
conflicts=('vulkan-mesa-layer')
|
||
replaces=('vulkan-mesa-layer')
|
||
|
||
_install fakeinstall/usr/share/vulkan/explicit_layer.d
|
||
_install fakeinstall/usr/share/vulkan/implicit_layer.d
|
||
_install fakeinstall/usr/lib/libVkLayer_*.so
|
||
_install fakeinstall/usr/bin/mesa-overlay-control.py
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_opencl-mesa() {
|
||
pkgdesc="OpenCL support with clover and rusticl for mesa drivers"
|
||
depends=('libdrm' 'libclc' 'clang' 'expat' 'spirv-llvm-translator')
|
||
optdepends=('opencl-headers: headers necessary for OpenCL development')
|
||
provides=('opencl-driver')
|
||
|
||
_install fakeinstall/etc/OpenCL
|
||
_install fakeinstall/usr/lib/lib*OpenCL*
|
||
_install fakeinstall/usr/lib/gallium-pipe
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_vulkan-radeon() {
|
||
pkgdesc="Radeon's Vulkan mesa driver"
|
||
depends=('wayland' 'libx11' 'libxshmfence' 'libelf' 'libdrm' 'llvm-libs' 'systemd-libs')
|
||
optdepends=('vulkan-mesa-layers: additional vulkan layers')
|
||
provides=('vulkan-driver')
|
||
|
||
_install fakeinstall/usr/share/drirc.d/00-radv-defaults.conf
|
||
_install fakeinstall/usr/share/vulkan/icd.d/radeon_icd*.json
|
||
_install fakeinstall/usr/lib/libvulkan_radeon.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_vulkan-swrast() {
|
||
pkgdesc="Vulkan software rasteriser driver"
|
||
depends=('wayland' 'libx11' 'libxshmfence' 'libdrm' 'zstd' 'llvm-libs' 'systemd-libs' 'libunwind')
|
||
optdepends=('vulkan-mesa-layers: additional vulkan layers')
|
||
conflicts=('vulkan-mesa')
|
||
replaces=('vulkan-mesa')
|
||
provides=('vulkan-driver')
|
||
|
||
_install fakeinstall/usr/share/vulkan/icd.d/lvp_icd*.json
|
||
_install fakeinstall/usr/lib/libvulkan_lvp.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_vulkan-virtio() {
|
||
pkgdesc="Venus Vulkan mesa driver for Virtual Machines"
|
||
depends=('wayland' 'libx11' 'libxshmfence' 'libdrm' 'zstd' 'systemd-libs')
|
||
optdepends=('vulkan-mesa-layers: additional vulkan layers')
|
||
provides=('vulkan-driver')
|
||
|
||
_install fakeinstall/usr/share/vulkan/icd.d/virtio_icd*.json
|
||
_install fakeinstall/usr/lib/libvulkan_virtio.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_vulkan-broadcom() {
|
||
pkgdesc="Broadcom's Vulkan mesa driver"
|
||
depends=('wayland' 'libx11' 'libxshmfence' 'libdrm')
|
||
optdepends=('vulkan-mesa-layers: additional vulkan layers')
|
||
provides=('vulkan-driver')
|
||
|
||
_install fakeinstall/usr/share/vulkan/icd.d/broadcom_icd*.json
|
||
_install fakeinstall/usr/lib/libvulkan_broadcom.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_vulkan-panfrost() {
|
||
pkgdesc="Panfrost Vulkan mesa driver"
|
||
depends=('wayland' 'libx11' 'libxshmfence' 'libdrm')
|
||
optdepends=('vulkan-mesa-layers: additional vulkan layers')
|
||
provides=('vulkan-driver')
|
||
|
||
_install fakeinstall/usr/share/vulkan/icd.d/panfrost_icd*.json
|
||
_install fakeinstall/usr/lib/libvulkan_panfrost.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_libva-mesa-driver() {
|
||
pkgdesc="VA-API drivers"
|
||
depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'libelf' 'libxshmfence')
|
||
depends+=('libexpat.so')
|
||
provides=('libva-driver')
|
||
|
||
_install fakeinstall/usr/lib/dri/*_drv_video.so
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_mesa-vdpau() {
|
||
pkgdesc="VDPAU drivers"
|
||
depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'libelf' 'libxshmfence')
|
||
depends+=('libexpat.so')
|
||
provides=('vdpau-driver')
|
||
|
||
_install fakeinstall/usr/lib/vdpau
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|
||
|
||
package_mesa() {
|
||
depends=('libdrm' 'wayland' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'libelf'
|
||
'libomxil-bellagio' 'libunwind' 'llvm-libs' 'lm_sensors' 'libglvnd'
|
||
'zstd' 'vulkan-icd-loader')
|
||
depends+=('libsensors.so' 'libexpat.so')
|
||
optdepends=('opengl-man-pages: for the OpenGL API man pages'
|
||
'mesa-vdpau: for accelerated video playback'
|
||
'libva-mesa-driver: for accelerated video playback')
|
||
provides=('mesa-libgl' 'opengl-driver')
|
||
conflicts=('mesa-libgl')
|
||
replaces=('mesa-libgl')
|
||
|
||
_install fakeinstall/usr/share/drirc.d/00-mesa-defaults.conf
|
||
_install fakeinstall/usr/share/glvnd/egl_vendor.d/50_mesa.json
|
||
|
||
# ati-dri, nouveau-dri, intel-dri, svga-dri, swrast, swr
|
||
_install fakeinstall/usr/lib/dri/*_dri.so
|
||
|
||
_install fakeinstall/usr/lib/bellagio
|
||
_install fakeinstall/usr/lib/d3d
|
||
_install fakeinstall/usr/lib/lib{gbm,glapi}.so*
|
||
_install fakeinstall/usr/lib/libOSMesa.so*
|
||
|
||
_install fakeinstall/usr/include
|
||
rm -f fakeinstall/usr/lib/pkgconfig/{egl,gl}.pc
|
||
_install fakeinstall/usr/lib/pkgconfig
|
||
|
||
# libglvnd support
|
||
_install fakeinstall/usr/lib/libGLX_mesa.so*
|
||
_install fakeinstall/usr/lib/libEGL_mesa.so*
|
||
|
||
# indirect rendering
|
||
ln -s /usr/lib/libGLX_mesa.so.0 "${pkgdir}/usr/lib/libGLX_indirect.so.0"
|
||
|
||
# make sure there are no files left to install
|
||
find fakeinstall -depth -print0 | xargs -0 rmdir
|
||
|
||
install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
|
||
}
|