mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
65 lines
1.6 KiB
Bash
65 lines
1.6 KiB
Bash
# $Id$
|
|
# Maintainer: Christian Hesse <mail@eworm.de>
|
|
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Eivind Uggedal <eivind@uggedal.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - armv7 needs to be built with fPIC
|
|
|
|
pkgname=mpv
|
|
_commit=f1778d1f
|
|
pkgver=41859.gf1778d1f
|
|
pkgrel=1
|
|
pkgdesc='Video player based on MPlayer/mplayer2'
|
|
arch=('i686' 'x86_64')
|
|
license=('GPL')
|
|
url='http://mpv.io'
|
|
depends=(
|
|
'ffmpeg' 'lcms2' 'libcdio-paranoia' 'libgl' 'enca' 'libxss'
|
|
'libxinerama' 'libxv' 'libxkbcommon' 'libva' 'wayland' 'libcaca'
|
|
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua52' 'libdvdnav'
|
|
'libguess' 'libxrandr' 'jack' 'smbclient' 'rubberband'
|
|
)
|
|
makedepends=('mesa' 'python-docutils' 'ladspa' 'hardening-wrapper')
|
|
optdepends=('youtube-dl: for video-sharing websites playback')
|
|
options=('!emptydirs' '!buildflags')
|
|
install=mpv.install
|
|
source=("git://github.com/mpv-player/mpv.git#commit=${_commit}")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
|
|
echo "$(git rev-list --count HEAD).g${_commit}"
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
|
|
./bootstrap.py
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
|
|
[[ $CARCH == "armv7h" ]] && CFLAGS+=" -fPIC" && CXXFLAGS+=" -fPIC"
|
|
|
|
./waf configure --prefix=/usr \
|
|
--confdir=/etc/mpv \
|
|
--enable-zsh-comp \
|
|
--enable-libmpv-shared \
|
|
--enable-cdda
|
|
|
|
./waf build
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
./waf install --destdir="$pkgdir"
|
|
|
|
install -d "$pkgdir"/usr/share/doc/mpv/examples
|
|
install -m644 etc/{input,example}.conf \
|
|
"$pkgdir"/usr/share/doc/mpv/examples
|
|
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
|
|
"$pkgdir"/usr/share/doc/mpv
|
|
}
|