mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
138 lines
3.7 KiB
Bash
138 lines
3.7 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove makedepend on valgrind
|
|
|
|
pkgbase=pipewire
|
|
pkgname=(pipewire alsa-card-profiles pipewire-docs pipewire-alsa pipewire-jack
|
|
pipewire-pulse gst-plugin-pipewire)
|
|
pkgver=0.3.22
|
|
pkgrel=2
|
|
epoch=1
|
|
pkgdesc="Low-latency audio/video router and processor"
|
|
url="https://pipewire.org"
|
|
license=(LGPL)
|
|
arch=(x86_64)
|
|
makedepends=(git meson doxygen graphviz xmltoman jack2 libpulse
|
|
alsa-lib gst-plugins-base rtkit dbus sdl2 ncurses libsndfile
|
|
bluez-libs sbc libldac libopenaptx libfdk-aac)
|
|
checkdepends=(desktop-file-utils)
|
|
_commit=22d563720a7f6ba7bdf59950f8c14488d80dfa95 # tags/0.3.22
|
|
source=("git+https://github.com/PipeWire/pipewire#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgbase
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgbase
|
|
|
|
# https://gitlab.gnome.org/GNOME/gnome-shell/-/issues/3810#note_1048367
|
|
git cherry-pick -n 3673265ae20d7b59e89cad6c5238c232796731b2
|
|
}
|
|
|
|
build() {
|
|
arch-meson $pkgbase build \
|
|
-D docs=true \
|
|
-D udevrulesdir=/usr/lib/udev/rules.d
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
meson test -C build --print-errorlogs
|
|
}
|
|
|
|
_pick() {
|
|
local p="$1" f d; shift
|
|
for f; do
|
|
d="$srcdir/$p/${f#$pkgdir/}"
|
|
mkdir -p "$(dirname "$d")"
|
|
mv "$f" "$d"
|
|
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
|
|
done
|
|
}
|
|
|
|
_ver=${pkgver:0:3}
|
|
|
|
package_pipewire() {
|
|
depends=(rtkit alsa-card-profiles libdbus-1.so libncursesw.so libsndfile.so
|
|
libudev.so libasound.so libsystemd.so libbluetooth.so libsbc.so
|
|
libldacBT_enc.so libopenaptx.so libfdk-aac.so)
|
|
optdepends=('pipewire-docs: Documentation'
|
|
'pipewire-alsa: ALSA configuration'
|
|
'pipewire-jack: JACK support'
|
|
'pipewire-pulse: PulseAudio replacement'
|
|
'gst-plugin-pipewire: GStreamer support')
|
|
provides=(libpipewire-$_ver.so)
|
|
backup=(etc/pipewire/{pipewire{,-pulse},client{,-rt}}.conf
|
|
etc/pipewire/media-session.d/media-session.conf
|
|
etc/pipewire/media-session.d/{alsa,bluez,v4l2}-monitor.conf)
|
|
install=pipewire.install
|
|
|
|
DESTDIR="$pkgdir" meson install -C build
|
|
|
|
cd "$pkgdir"
|
|
|
|
_pick acp usr/lib/udev
|
|
_pick acp usr/share/alsa-card-profile
|
|
|
|
_pick docs usr/share/doc
|
|
|
|
_pick jack etc/pipewire/{jack.conf,media-session.d/with-jack}
|
|
_pick jack usr/bin/pw-jack usr/lib/pipewire-$_ver/jack
|
|
_pick jack usr/lib/spa-0.2/jack
|
|
_pick jack usr/share/man/man1/pw-jack.1
|
|
|
|
_pick pulse etc/pipewire/media-session.d/with-pulseaudio
|
|
|
|
_pick gst usr/lib/gstreamer-1.0
|
|
}
|
|
|
|
package_alsa-card-profiles() {
|
|
pkgdesc+=" - ALSA card profiles"
|
|
mv acp/* "$pkgdir"
|
|
}
|
|
|
|
package_pipewire-docs() {
|
|
pkgdesc+=" - documentation"
|
|
mv docs/* "$pkgdir"
|
|
}
|
|
|
|
package_pipewire-alsa() {
|
|
pkgdesc+=" - ALSA configuration"
|
|
depends=(pipewire)
|
|
provides=(pulseaudio-alsa)
|
|
|
|
mkdir -p "$pkgdir/etc/alsa/conf.d"
|
|
ln -st "$pkgdir/etc/alsa/conf.d" \
|
|
/usr/share/alsa/alsa.conf.d/{50-pipewire,99-pipewire-default}.conf
|
|
install -Dm644 /dev/null "$pkgdir/etc/pipewire/media-session.d/with-alsa"
|
|
}
|
|
|
|
package_pipewire-jack() {
|
|
pkgdesc+=" - JACK support"
|
|
depends=(pipewire libpipewire-$_ver.so libjack.so)
|
|
backup=(etc/pipewire/jack.conf)
|
|
mv jack/* "$pkgdir"
|
|
}
|
|
|
|
package_pipewire-pulse() {
|
|
pkgdesc+=" - PulseAudio replacement"
|
|
depends=(pipewire libpulse)
|
|
provides=(pulseaudio pulseaudio-bluetooth)
|
|
conflicts=(pulseaudio pulseaudio-bluetooth)
|
|
install=pipewire-pulse.install
|
|
mv pulse/* "$pkgdir"
|
|
}
|
|
|
|
package_gst-plugin-pipewire() {
|
|
pkgdesc="Multimedia graph framework - pipewire plugin"
|
|
depends=(pipewire libpipewire-$_ver.so gst-plugins-base-libs)
|
|
mv gst/* "$pkgdir"
|
|
}
|
|
|
|
# vim:set sw=2 et:
|