mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
61 lines
1.9 KiB
Bash
61 lines
1.9 KiB
Bash
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
# Contributor: Ray Rashif <schiv@archlinux.org>
|
|
# Contributor: speps <speps at aur dot archlinux dot org>
|
|
# Contributor: Philipp Überbacher <hollunder at gmx dot at>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set -DCONFIG_SSE=OFF
|
|
|
|
pkgname=qtractor
|
|
pkgver=0.9.31
|
|
pkgrel=1
|
|
pkgdesc="Audio/MIDI multitrack sequencer"
|
|
arch=(x86_64)
|
|
url="https://qtractor.sourceforge.io/"
|
|
license=(GPL2)
|
|
groups=(pro-audio)
|
|
depends=(glibc gcc-libs hicolor-icon-theme libmad libxcb qt6-base qt6-svg zlib)
|
|
makedepends=(alsa-lib aubio clap cmake dssi jack ladspa liblo libogg
|
|
libsamplerate libsndfile libvorbis lilv lv2 qt6-tools rubberband suil vst3sdk)
|
|
optdepends=(
|
|
'new-session-manager: for session management'
|
|
'qt6-wayland: for native wayland support'
|
|
)
|
|
provides=(clap-host dssi-host ladspa-host lv2-host vst-host vst3-host)
|
|
source=(https://github.com/rncbc/$pkgname/archive/refs/tags/${pkgname}_${pkgver//./_}.tar.gz)
|
|
sha512sums=('20390e6035f5f3b7ac8af786d1fb72d9f02955df5e958f946a37914ffb18c50084598c5c878c5dcd9a3eabc29213cd5121712ce7bffa49bc1b7b99a71515c20d')
|
|
b2sums=('09cd3f709ffc3a6ea13e2cf0bbf474cf5be6e67f9ecfd8738eddadebe0e3cdee7abe55712425437095bbf385a7f413a324a9bc7b88077adede2f162c9177f378')
|
|
|
|
build() {
|
|
local cmake_options=(
|
|
-B build
|
|
-DCMAKE_BUILD_TYPE=None
|
|
-DCMAKE_INSTALL_PREFIX=/usr
|
|
-DCONFIG_QT6=ON
|
|
-DCONFIG_SSE=OFF
|
|
-S $pkgname-${pkgname}_${pkgver//./_}
|
|
-Wno-dev
|
|
)
|
|
|
|
cmake "${cmake_options[@]}"
|
|
cmake --build build --verbose
|
|
}
|
|
|
|
package() {
|
|
depends+=(
|
|
alsa-lib libasound.so
|
|
aubio libaubio.so
|
|
jack libjack.so
|
|
liblo liblo.so
|
|
libogg libogg.so
|
|
libsamplerate libsamplerate.so
|
|
libsndfile libsndfile.so
|
|
libvorbis libvorbisenc.so libvorbisfile.so libvorbis.so
|
|
lilv liblilv-0.so
|
|
rubberband librubberband.so
|
|
)
|
|
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
install -vDm 644 $pkgname-${pkgname}_${pkgver//./_}/{README,README.VST} -t "$pkgdir/usr/share/doc/$pkgname/"
|
|
}
|