mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
70 lines
1.9 KiB
Bash
70 lines
1.9 KiB
Bash
# $Id$
|
|
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - re-enabled --disable-silent-rules, needed for v5 and v6 to build
|
|
# - use --disable-jit to solve segfaults
|
|
|
|
pkgbase=webkitgtk
|
|
pkgname=(webkitgtk webkitgtk2)
|
|
pkgver=2.2.5
|
|
pkgrel=2.1
|
|
pkgdesc="GTK+ Web content engine library"
|
|
arch=(i686 x86_64)
|
|
url="http://webkitgtk.org/"
|
|
license=(custom)
|
|
depends=(libxt libxslt sqlite libsoup enchant libgl geoclue gst-plugins-base-libs
|
|
libsecret libwebp harfbuzz-icu)
|
|
makedepends=(gtk3 gtk2 gperf gobject-introspection python mesa ruby gtk-doc)
|
|
options=(!emptydirs)
|
|
source=(http://webkitgtk.org/releases/$pkgbase-${pkgver}.tar.xz)
|
|
sha256sums=('c710994a1ed0ec78f746a05ae7dc65369ed56d7475f0de576ca7a73ad9c6e670')
|
|
|
|
prepare() {
|
|
mkdir build-gtk{,2}
|
|
}
|
|
|
|
_build() (
|
|
_ver="$1"; shift
|
|
cd build-${_ver}
|
|
|
|
../$pkgbase-$pkgver/configure --prefix=/usr \
|
|
--libexecdir=/usr/lib/webkit${_ver} \
|
|
--enable-introspection --disable-jit \
|
|
"$@"
|
|
|
|
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
|
|
sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
|
|
make all stamp-po
|
|
)
|
|
|
|
build() {
|
|
_build gtk --enable-gtk-doc
|
|
_build gtk2 --disable-webkit2 --with-gtk=2.0
|
|
}
|
|
|
|
package_webkitgtk() {
|
|
depends+=(gtk3)
|
|
optdepends=('gtk2: Netscape plugin support')
|
|
provides=("webkitgtk3=${pkgver}" "libwebkit3=${pkgver}")
|
|
conflicts=(webkitgtk3 libwebkit3)
|
|
replaces=(webkitgtk3 libwebkit3)
|
|
|
|
make -C build-gtk -j1 DESTDIR="$pkgdir" install
|
|
install -Dm644 $pkgbase-$pkgver/Source/WebKit/LICENSE \
|
|
"$pkgdir/usr/share/licenses/webkitgtk/LICENSE"
|
|
}
|
|
|
|
package_webkitgtk2() {
|
|
pkgdesc+=" for GTK2"
|
|
depends+=(gtk2)
|
|
provides=("libwebkit=${pkgver}")
|
|
conflicts=(libwebkit)
|
|
replaces=(libwebkit)
|
|
|
|
make -C build-gtk2 -j1 DESTDIR="$pkgdir" install
|
|
install -Dm644 $pkgbase-$pkgver/Source/WebKit/LICENSE \
|
|
"$pkgdir/usr/share/licenses/webkitgtk2/LICENSE"
|
|
}
|