mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
89 lines
2.7 KiB
Bash
89 lines
2.7 KiB
Bash
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Thomas Dziedzic < gostrc at gmail >
|
|
# Contributor: James Campos <james.r.campos@gmail.com>
|
|
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
|
|
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
|
|
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
|
|
# Contributor: TIanyi Cui <tianyicui@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set config and gyp flags
|
|
# - patch to link libatomic for v6
|
|
|
|
buildarch=28
|
|
|
|
pkgname=nodejs
|
|
pkgver=10.11.0
|
|
pkgrel=1
|
|
pkgdesc='Evented I/O for V8 javascript'
|
|
arch=('x86_64')
|
|
url='http://nodejs.org/'
|
|
license=('MIT')
|
|
depends=('openssl' 'zlib' 'icu' 'libuv' 'http-parser' 'c-ares' 'libnghttp2') # 'v8')
|
|
makedepends=('python2' 'procps-ng')
|
|
optdepends=('npm: nodejs package manager')
|
|
source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz"
|
|
'atomic.patch')
|
|
sha512sums=('6bf6e7f7375d468752b173faeaf7e769615c8a9d83420ed1fa0d9245dfe1117f5942a63ade3f9fb3c92ed2141eee1d31f8a00b2fc0644284a8da40e40d4b8cd8'
|
|
'fa6d8a03f397b170353cdf2ca6578b5173d1cbc1f588e404e5aab1e34c05d99ad4fe2f1cf28cbbeb3bf8b7563960f37f9469c312484bdbe41c20d6fe05121c95')
|
|
|
|
prepare() {
|
|
cd node-$pkgver
|
|
|
|
msg 'Fixing for python2 name'
|
|
find -type f -exec sed \
|
|
-e 's_^#!/usr/bin/env python$_&2_' \
|
|
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
|
|
-e 's_^#!/usr/bin/python$_&2_' \
|
|
-e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
|
|
-e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
|
|
-e "s_'python'_'python2'_" -i {} \;
|
|
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
|
|
|
|
if [[ $CARCH == "armv6h" ]]; then
|
|
patch -p0 -i ../atomic.patch
|
|
fi
|
|
}
|
|
|
|
build() {
|
|
cd node-$pkgver
|
|
|
|
export PYTHON=python2
|
|
|
|
[[ "$CARCH" == "armv6h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfp" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=6 -Darm_fpu=vfpv2"
|
|
[[ "$CARCH" == "armv7h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfpv3-d16" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=7 -Darm_fpu=vfpv3-d16"
|
|
|
|
./configure \
|
|
--prefix=/usr \
|
|
--with-intl=system-icu \
|
|
--without-npm \
|
|
--shared-openssl \
|
|
--shared-zlib \
|
|
--shared-libuv \
|
|
--shared-http-parser \
|
|
--shared-cares \
|
|
--shared-nghttp2 \
|
|
${CONFIG}
|
|
# --shared-v8
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd node-$pkgver
|
|
# Expected failure: https://github.com/nodejs/node/issues/11627
|
|
make test || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd node-$pkgver
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -D -m644 LICENSE \
|
|
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|