mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
71 lines
2.2 KiB
Bash
71 lines
2.2 KiB
Bash
# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
|
||
# Maintainer: Caleb Maclennan <caleb@alerque.com>
|
||
# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
|
||
|
||
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
||
# - remove makedepend on pandoc, don't build/install manpages
|
||
|
||
pkgname=eza
|
||
pkgver=0.19.4
|
||
pkgrel=1
|
||
pkgdesc="A modern replacement for ls (community fork of exa)"
|
||
url="https://github.com/eza-community/eza"
|
||
arch=(x86_64)
|
||
license=(MIT)
|
||
provides=(exa)
|
||
replaces=(exa)
|
||
conflicts=(exa)
|
||
depends=(gcc-libs # libgcc_s.so
|
||
glibc # libc.so libm.so
|
||
libgit2
|
||
zlib)
|
||
makedepends=(cargo)
|
||
source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
|
||
sha256sums=('c0094b3ee230702d4dd983045e38ea2bd96375c16381c0206c88fae82fb551a4')
|
||
b2sums=('ffe9d5cfefde538be4efaadcc58f661b50eccabb8ec5382d562a3dee37c6c3508996b463be2123718bf6e30e6305b757a1c4e49f9a9cc2e6b212751a92018abf')
|
||
|
||
prepare() {
|
||
cd "${pkgname}-${pkgver}"
|
||
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
||
}
|
||
|
||
build() {
|
||
cd "${pkgname}-${pkgver}"
|
||
# Make sure the build fails if our system libgit2 is out
|
||
# of range rather than silently starting to vendor it.
|
||
export LIBGIT2_NO_VENDOR=1
|
||
CFLAGS+=' -ffat-lto-objects'
|
||
cargo build --frozen --release
|
||
mkdir -p target/man
|
||
#for manpage in eza.1 eza_colors.5 eza_colors-explanation.5; do
|
||
# pandoc --standalone -f markdown -t man "man/${manpage}.md" > "target/man/${manpage}"
|
||
#done
|
||
}
|
||
|
||
check() {
|
||
cd "${pkgname}-${pkgver}"
|
||
cargo test --frozen
|
||
target/release/eza -la
|
||
}
|
||
|
||
|
||
package() {
|
||
depends+=(libgit2.so
|
||
libz.so)
|
||
cd "${pkgname}-${pkgver}"
|
||
install -Dm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
|
||
ln -s eza "${pkgdir}/usr/bin/exa"
|
||
|
||
# install completions
|
||
install -Dm644 "completions/bash/${pkgname}" -t "${pkgdir}/usr/share/bash-completion/completions"
|
||
install -Dm644 "completions/zsh/_${pkgname}" -t "${pkgdir}/usr/share/zsh/site-functions/"
|
||
install -Dm644 "completions/fish/${pkgname}.fish" -t "${pkgdir}/usr/share/fish/vendor_completions.d"
|
||
|
||
# install man pages
|
||
#install -Dm644 target/man/*.1 -t "${pkgdir}/usr/share/man/man1"
|
||
#install -Dm644 target/man/*.5 -t "${pkgdir}/usr/share/man/man5"
|
||
|
||
install -Dm644 LICEN?E "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
||
}
|
||
|
||
# vim: ts=2 sw=2 et:
|