mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
60 lines
1.9 KiB
Bash
60 lines
1.9 KiB
Bash
# $Id: PKGBUILD 240297 2015-06-03 10:22:03Z fyan $
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - disable jit on v5/v6
|
|
# - disable OpenGL
|
|
|
|
highmem=1
|
|
|
|
pkgname=qt5-webkit
|
|
_qtver=5.212.0-alpha2
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=2
|
|
arch=(i686 x86_64)
|
|
url='http://qt-project.org/'
|
|
license=(GPL3 LGPL3 FDL custom)
|
|
pkgdesc='Classes for a WebKit2 based implementation and a new QML API'
|
|
depends=(qt5-location qt5-sensors qt5-webchannel libwebp libxslt libxcomposite gst-plugins-base hyphen)
|
|
makedepends=(cmake ruby gperf python2 qt5-doc qt5-tools)
|
|
optdepends=('gst-plugins-good: Webm codec support')
|
|
conflicts=(qt5-webkit-ng)
|
|
replaces=(qt5-webkit-ng)
|
|
groups=(qt qt5)
|
|
_pkgfqn="${pkgname/5-/}-opensource-src-${_qtver}"
|
|
source=("https://github.com/annulen/webkit/releases/download/qtwebkit-$_qtver/qtwebkit-$_qtver.tar.xz")
|
|
sha256sums=('f8f901de567e11fc5659402b6b827eac75505ff9c5072d8e919aa306003f8f8a')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
|
|
|
|
cmake ../qtwebkit-$_qtver \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DPORT=Qt \
|
|
-DENABLE_TOOLS=OFF \
|
|
-DENABLE_OPENGL=OFF $CONFIG
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -d "$pkgdir"/usr/share/licenses
|
|
ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
|
|
|
|
# Fix pkgconfig files
|
|
sed -e 's|qt/Qt5WebKit|qt/QtWebKit|' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKit.pc
|
|
sed -e 's|qt/Qt5WebKitWidgets|qt/QtWebKitWidgets|' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKitWidgets.pc
|
|
sed -e '/Name/a Description: Qt WebKit module' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKit.pc
|
|
sed -e '/Name/a Description: Qt WebKitWidgets module' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKitWidgets.pc
|
|
}
|