mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
75 lines
2.2 KiB
Bash
75 lines
2.2 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Eric Bélanger <eric@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - do not use LLINT assembly for v5/v6
|
|
|
|
highmem=1
|
|
|
|
pkgname=webkit2gtk
|
|
pkgver=2.28.4
|
|
pkgrel=1
|
|
pkgdesc="GTK+ Web content engine library"
|
|
arch=(x86_64)
|
|
url="https://webkitgtk.org/"
|
|
license=(custom)
|
|
depends=(libxt libxslt enchant gst-plugins-base-libs libsecret libwebp openjpeg2
|
|
harfbuzz-icu gtk3 libnotify hyphen woff2 libwpe wpebackend-fdo
|
|
bubblewrap xdg-dbus-proxy)
|
|
makedepends=(gperf gobject-introspection ruby gtk-doc cmake python geoclue
|
|
gst-plugins-bad ninja)
|
|
optdepends=('geoclue: Geolocation support'
|
|
'gst-plugins-good: media decoding'
|
|
'gst-plugins-bad: media decoding'
|
|
'gst-libav: nonfree media decoding')
|
|
source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
|
|
sha256sums=('821952e8c9303ed752f1fb1d4283f612c25249d00d705d2b79c2db1bc49c9464'
|
|
'SKIP')
|
|
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'
|
|
'5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')
|
|
|
|
prepare() {
|
|
cd webkitgtk-$pkgver
|
|
}
|
|
|
|
build() {
|
|
# do not use LLINT assembly for v5/v6
|
|
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
|
|
|
|
CFLAGS+=" $CPPFLAGS"
|
|
CXXFLAGS+=" $CPPFLAGS"
|
|
cmake -Hwebkitgtk-$pkgver -Bbuild -G Ninja \
|
|
-DPORT=GTK \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_SKIP_RPATH=ON \
|
|
-DENABLE_GTKDOC=ON \
|
|
-DENABLE_MINIBROWSER=ON \
|
|
-DLIBEXEC_INSTALL_DIR=/usr/lib \
|
|
-DLIB_INSTALL_DIR=/usr/lib \
|
|
$CONFIG
|
|
cmake --build build
|
|
}
|
|
|
|
check() {
|
|
: cmake --build build --target tests
|
|
}
|
|
|
|
package() {
|
|
depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
|
|
provides+=(libjavascriptcoregtk-4.0.so libwebkit2gtk-4.0.so)
|
|
|
|
DESTDIR="$pkgdir" cmake --build build --target install
|
|
|
|
cd webkitgtk-$pkgver
|
|
find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
|
|
while IFS= read -d $'\0' -r _f; do
|
|
echo "### $_f ###"
|
|
cat "$_f"
|
|
echo
|
|
done |
|
|
install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
}
|
|
|
|
# vim:set sw=2 et:
|