mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-18 22:54:00 +00:00
48 lines
1.1 KiB
Bash
48 lines
1.1 KiB
Bash
# $Id$
|
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Maintainer: Jan de Groot <jgc@archlinux.org>
|
|
# Contributor: Ionut Biru <ibiru@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - drop valgrind makedepend
|
|
|
|
pkgname=orc
|
|
pkgver=0.4.26+2+g249c709
|
|
pkgrel=1
|
|
pkgdesc="Optimized Inner Loop Runtime Compiler"
|
|
url="https://cgit.freedesktop.org/gstreamer/orc"
|
|
arch=(i686 x86_64)
|
|
license=(custom)
|
|
depends=(glibc)
|
|
makedepends=(git gtk-doc)
|
|
_commit=249c709e90458ecef7a068df553ea41a83eedf0f # master
|
|
source=("git+https://anongit.freedesktop.org/git/gstreamer/orc#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/^orc-//;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
./configure --prefix=/usr --disable-static --enable-gtk-doc
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd $pkgname
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
}
|