mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
76 lines
2.1 KiB
Bash
76 lines
2.1 KiB
Bash
# $Id$
|
|
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - use --disable-jit to solve segfaults
|
|
|
|
pkgbase=webkitgtk
|
|
pkgname=(webkitgtk webkitgtk2)
|
|
pkgver=2.4.1
|
|
pkgrel=1
|
|
pkgdesc="GTK+ Web content engine library"
|
|
arch=(i686 x86_64)
|
|
url="http://webkitgtk.org/"
|
|
license=(custom)
|
|
depends=(libxt libxslt sqlite libsoup enchant libgl geoclue gst-plugins-base-libs
|
|
libsecret libwebp harfbuzz-icu)
|
|
makedepends=(gtk3 gtk2 gperf gobject-introspection python mesa ruby gtk-doc)
|
|
optdepends=('gst-plugins-base: free media decoding'
|
|
'gst-plugins-good: media decoding'
|
|
'gst-libav: nonfree media decoding')
|
|
options=(!emptydirs)
|
|
source=(http://webkitgtk.org/releases/$pkgbase-${pkgver}.tar.xz
|
|
fix-pretty-quotes.patch)
|
|
sha256sums=('6eed5d41ecdcfbafe3c2fbb0f0b79b9cda87a5ea0e7d0938afb6c6c82996e2f7'
|
|
'56316228bbbf0b7ebcbe210a35120f4e72cb9c1b680dd82cc2bde0f4549245e6')
|
|
|
|
prepare() {
|
|
mkdir build-gtk{,2}
|
|
cd $pkgbase-$pkgver
|
|
patch -Np0 -i ../fix-pretty-quotes.patch
|
|
}
|
|
|
|
_build() (
|
|
_ver="$1"; shift
|
|
cd build-${_ver}
|
|
|
|
../$pkgbase-$pkgver/configure --prefix=/usr \
|
|
--libexecdir=/usr/lib/webkit${_ver} \
|
|
--enable-introspection --disable-jit \
|
|
"$@"
|
|
|
|
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
|
|
sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
|
|
make all stamp-po
|
|
)
|
|
|
|
build() {
|
|
_build gtk --enable-gtk-doc
|
|
_build gtk2 --disable-webkit2 --with-gtk=2.0
|
|
}
|
|
|
|
package_webkitgtk() {
|
|
depends+=(gtk3)
|
|
optdepends+=('gtk2: Netscape plugin support')
|
|
provides=("webkitgtk3=${pkgver}" "libwebkit3=${pkgver}")
|
|
conflicts=(webkitgtk3 libwebkit3)
|
|
replaces=(webkitgtk3 libwebkit3)
|
|
|
|
make -C build-gtk -j1 DESTDIR="$pkgdir" install
|
|
install -Dm644 $pkgbase-$pkgver/Source/WebKit/LICENSE \
|
|
"$pkgdir/usr/share/licenses/webkitgtk/LICENSE"
|
|
}
|
|
|
|
package_webkitgtk2() {
|
|
pkgdesc+=" for GTK2"
|
|
depends+=(gtk2)
|
|
provides=("libwebkit=${pkgver}")
|
|
conflicts=(libwebkit)
|
|
replaces=(libwebkit)
|
|
|
|
make -C build-gtk2 -j1 DESTDIR="$pkgdir" install
|
|
install -Dm644 $pkgbase-$pkgver/Source/WebKit/LICENSE \
|
|
"$pkgdir/usr/share/licenses/webkitgtk2/LICENSE"
|
|
}
|