mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
89 lines
2.8 KiB
Bash
89 lines
2.8 KiB
Bash
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Thomas Dziedzic < gostrc at gmail >
|
|
# Contributor: James Campos <james.r.campos@gmail.com>
|
|
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
|
|
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
|
|
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
|
|
# Contributor: TIanyi Cui <tianyicui@gmail.com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - set config and gyp flags
|
|
# - patch to link libatomic for v6
|
|
|
|
buildarch=28
|
|
|
|
pkgname=nodejs
|
|
pkgver=12.13.0
|
|
pkgrel=2
|
|
pkgdesc='Evented I/O for V8 javascript'
|
|
arch=('x86_64')
|
|
url='https://nodejs.org/'
|
|
license=('MIT')
|
|
depends=('openssl' 'zlib' 'icu' 'libuv' 'c-ares' 'libnghttp2') # 'http-parser' 'v8')
|
|
makedepends=('python2' 'procps-ng')
|
|
optdepends=('npm: nodejs package manager')
|
|
source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz"
|
|
'atomic.patch')
|
|
sha512sums=('4698b7f9fed657ca1707c33dbf5892dea396c3e049ece38e77db02ce80573ee1ad548d1103cdc963861d814288e579ae6332f9885258d511c4861df9ce40b7c3'
|
|
'3d7378b80a9729f5dd5c6c7446531244a67bd6021ccf6feb270af2b698d9bd2ff3c6bf84f8d0a6eb3671c59ea920de8ec081cac0b705236b474b61427f5c1e39')
|
|
|
|
prepare() {
|
|
cd node-$pkgver
|
|
|
|
msg 'Fixing for python2 name'
|
|
find -type f -exec sed \
|
|
-e 's_^#!/usr/bin/env python$_&2_' \
|
|
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
|
|
-e 's_^#!/usr/bin/python$_&2_' \
|
|
-e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
|
|
-e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
|
|
-e "s_'python'_'python2'_" -i {} \;
|
|
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
|
|
|
|
if [[ $CARCH == "armv6h" ]]; then
|
|
patch -p0 -i ../atomic.patch
|
|
fi
|
|
}
|
|
|
|
build() {
|
|
cd node-$pkgver
|
|
|
|
export PYTHON=python2
|
|
|
|
[[ "$CARCH" == "armv6h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfp" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=6 -Darm_fpu=vfpv2"
|
|
[[ "$CARCH" == "armv7h" ]] && export CONFIG="--with-arm-float-abi=hard --with-arm-fpu=vfpv3-d16" && export GYPFLAGS="-Darm_thumb -Darm_float_abi=hard -Darm_version=7 -Darm_fpu=vfpv3-d16"
|
|
|
|
./configure \
|
|
--prefix=/usr \
|
|
--with-intl=system-icu \
|
|
--without-npm \
|
|
--shared-openssl \
|
|
--shared-zlib \
|
|
--shared-libuv \
|
|
--experimental-http-parser \
|
|
--shared-cares \
|
|
--shared-nghttp2 \
|
|
${CONFIG}
|
|
# --shared-v8
|
|
# --shared-http-parser
|
|
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd node-$pkgver
|
|
# Expected failure: https://github.com/nodejs/node/issues/11627
|
|
make test || warning "Tests failed"
|
|
}
|
|
|
|
package() {
|
|
cd node-$pkgver
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -D -m644 LICENSE \
|
|
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|