mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-11-08 22:45:43 +00:00
58 lines
1.8 KiB
Bash
58 lines
1.8 KiB
Bash
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - cmake with -DWOLFSSL_SHA3=ON, required and not set by default for v7
|
|
|
|
# WARNING: This upstream **does not** guarantee ABI stability. Expect soname changes in patch-level version bumps (https://github.com/wolfSSL/wolfssl/issues/6928)
|
|
pkgname=wolfssl
|
|
pkgver=5.7.0
|
|
pkgrel=1
|
|
pkgdesc="Lightweight, portable, C-language-based SSL/TLS library"
|
|
arch=(x86_64)
|
|
url="https://www.wolfssl.com/"
|
|
license=(GPL-2.0-or-later)
|
|
depends=(glibc)
|
|
makedepends=(cmake)
|
|
provides=(libwolfssl.so)
|
|
source=(
|
|
$pkgname-$pkgver-stable.tar.gz::https://github.com/$pkgname/$pkgname/archive/refs/tags/v$pkgver-stable.tar.gz
|
|
https://github.com/$pkgname/$pkgname/releases/download/v$pkgver-stable/$pkgname-$pkgver-stable.tar.gz.asc
|
|
)
|
|
sha512sums=('52cc7bdda7e3cfbea7c60fad1e2b1565d7057607bbb66014ef03643a75e78777d10d53799fba314bab37e245b7e8a60e29c6f4177070ed44536a898e04b27b44'
|
|
'SKIP')
|
|
b2sums=('a85342264022d9f1ab3cd49bd282cbd9f2ef4fa90eda69ebd145a412f1557ed6d0ca5620f5a916fe1bf8c546c1d3ef0d01c80ec90722d49059683620ccbcdf1b'
|
|
'SKIP')
|
|
validpgpkeys=(
|
|
A2A48E7BCB96C5BECB987314EBC80E415CA29677 # wolfSSL <secure@wolfssl.com>
|
|
)
|
|
|
|
build() {
|
|
local cmake_options=(
|
|
-B build
|
|
-D CMAKE_BUILD_TYPE=None
|
|
-D CMAKE_INSTALL_PREFIX=/usr
|
|
-D WOLFSSL_CURVE25519=ON
|
|
-D WOLFSSL_CURVE448=ON
|
|
-D WOLFSSL_ED25519=ON
|
|
-D WOLFSSL_ED448=ON
|
|
-D WOLFSSL_SHA3=ON
|
|
-D WOLFSSL_REPRODUCIBLE_BUILD=ON
|
|
-D WOLFSSL_SNI=ON
|
|
-D WARNING_C_FLAGS="$CFLAGS"
|
|
-W no-dev
|
|
-S $pkgname-$pkgver-stable
|
|
)
|
|
|
|
cmake "${cmake_options[@]}"
|
|
cmake --build build --verbose
|
|
}
|
|
|
|
check() {
|
|
cd build
|
|
./wolfcrypt/test/testwolfcrypt
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
install -vDm 644 $pkgname-$pkgver-stable/{README,ChangeLog}.md -t "$pkgdir/usr/share/doc/$pkgname/"
|
|
}
|