mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
49 lines
1.2 KiB
Bash
49 lines
1.2 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Chocobo1 <chocobo1 AT archlinux DOT net>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - cmake with -DAOM_TARGET_CPU=generic for !AArch64
|
|
|
|
pkgname=aom
|
|
pkgver=2.0.1
|
|
pkgrel=1
|
|
pkgdesc="Alliance for Open Media video codec"
|
|
url="https://aomedia.org/"
|
|
arch=(x86_64)
|
|
license=(BSD custom:PATENTS)
|
|
depends=(gcc-libs)
|
|
makedepends=(git cmake ninja doxygen yasm)
|
|
provides=(libaom.so)
|
|
_commit=b52ee6d44adaef8a08f6984390de050d64df9faa # tags/v2.0.1^0
|
|
source=("git+https://aomedia.googlesource.com/aom#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/^v//;s/-errata/.errata/;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
}
|
|
|
|
build() {
|
|
[[ $CARCH != "aarch64" ]] && CONFIG="-DAOM_TARGET_CPU=generic"
|
|
cmake -S $pkgname -B build -G Ninja \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DBUILD_SHARED_LIBS=1 \
|
|
-DENABLE_TESTS=0 $CONFIG
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
mkdir -p "$pkgdir/usr/share/doc"
|
|
cp -r build/docs/html "$pkgdir/usr/share/doc/$pkgname"
|
|
|
|
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/{LICENSE,PATENTS}
|
|
}
|
|
|
|
# vim:set et sw=2:
|