mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
74 lines
2.6 KiB
Bash
74 lines
2.6 KiB
Bash
# $Id$
|
|
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
|
|
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
|
|
# Contributor: Dan Vratil <progdan@progdansoft.com>
|
|
# Contributor: thotypous <matiasΘarchlinux-br·org>
|
|
# Contributor: delor <bartekpiech gmail com>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch distributed botan version for ARM
|
|
# - drop valgrind optdepend
|
|
|
|
buildarch=12
|
|
|
|
pkgname=qtcreator
|
|
pkgver=4.6.2
|
|
_clangver=6.0.1
|
|
pkgrel=3
|
|
pkgdesc='Lightweight, cross-platform integrated development environment'
|
|
arch=(x86_64)
|
|
url='http://qt-project.org'
|
|
license=(LGPL)
|
|
depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 qt5-webengine clang=$_clangver qbs)
|
|
makedepends=(git mesa llvm)
|
|
options=(docs)
|
|
optdepends=('qt5-doc: integrated Qt documentation'
|
|
'qt5-examples: welcome page examples'
|
|
'qt5-translations: for other languages'
|
|
'gdb: debugger'
|
|
'cmake: cmake project support'
|
|
'x11-ssh-askpass: ssh support'
|
|
'git: git support'
|
|
'mercurial: mercurial support'
|
|
'bzr: bazaar support')
|
|
source=("http://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz"
|
|
qtcreatorbug-20721.patch::"http://code.qt.io/cgit/qt-creator/qt-creator.git/patch/?id=cb572773"
|
|
'0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch')
|
|
sha256sums=('bbaf667f51051c602df02e04c1d7369bef9553326d8377bc36a019ae718843cc'
|
|
'eadbc3a730c52e2fc75b494b48c41bcb2fe74d8eb2bbec1cdd0bd466d1acb967'
|
|
'56e6876f41ee8909ee197f7ab5a2bb18ad5a7fe26ce490a48cdf062fa199ffc6')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
|
|
cd qt-creator-opensource-src-$pkgver
|
|
# fix hardcoded libexec path
|
|
sed -e 's|libexec\/qtcreator|lib\/qtcreator|g' -i qtcreator.pri
|
|
# use system qbs
|
|
rm -r src/shared/qbs
|
|
# Fix widgets state saving with Qt 5.11.1
|
|
patch -p1 -i ../qtcreatorbug-20721.patch
|
|
|
|
git apply ../0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
qmake LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr CONFIG+=journald QMAKE_CFLAGS_ISYSTEM=-I \
|
|
DEFINES+=QBS_ENABLE_PROJECT_FILE_UPDATES "$srcdir"/qt-creator-opensource-src-$pkgver/qtcreator.pro
|
|
make
|
|
make docs
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
|
|
make INSTALL_ROOT="$pkgdir/usr/" install
|
|
make INSTALL_ROOT="$pkgdir/usr/" install_docs
|
|
|
|
install -Dm644 "$srcdir"/qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
|
|
}
|