PKGBUILDs/community/docker/PKGBUILD

# $Id$
# Maintainer: Sebastien "Seblu" Luttringer

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - ARM patches, adjustments

pkgname=docker
pkgver=0.11.1
pkgrel=1
epoch=1
pkgdesc='Pack, ship and run any application as a lightweight container'
arch=('x86_64')
url='http://www.docker.io/'
license=('Apache')
depends=('bridge-utils' 'iproute2' 'device-mapper' 'sqlite' 'systemd')
makedepends=('git' 'go' 'btrfs-progs')
optdepends=('btrfs-progs: btrfs backend support'
            'lxc: lxc backend support')
# don't strip binaries! A sha1 is used to check binary consistency.
options=('!strip')
install=$pkgname.install
source=("git+https://github.com/dotcloud/docker.git#tag=v$pkgver"
        '0001-ARM-as-allowed-architecture.patch'
        '0002-Fix-btrfs-detection-on-ARM.patch'
        '0003-setBridgeMacAddress-ARM-support.patch'
        '0004-Allow-missing-kcore.patch')
md5sums=('SKIP'
         'c003084f4cf0f754c868662a8bae95e8'
         'f3ed840798065ca2a40e40b07d5e4069'
         'f42c2001c85556830598a8ec07430d53'
         'e909f4cccd0e066be06538d0669fa4df')

prepare() {
  cd "docker"
  patch -p1 -i ../0001-ARM-as-allowed-architecture.patch
  patch -p1 -i ../0002-Fix-btrfs-detection-on-ARM.patch
  find . -name '*.go' | xargs sed --in-place= -e 's/\/\/ +build amd64/\/\/ +build arm/'
  find . -name '*.go' | xargs sed --in-place= -e 's/\/\/ +build !linux !amd64/\/\/ +build !linux !arm/'
  find . -name '*.go' | xargs sed --in-place= -e 's/\/\/ +build linux,amd64/\/\/ +build linux,arm/'
  # This patch is applicable after the seds.
  patch -p1 -i ../0003-setBridgeMacAddress-ARM-support.patch
  patch -p1 -i ../0004-Allow-missing-kcore.patch
}

build() {
  cd docker
  export AUTO_GOPATH=1
  ./hack/make.sh dynbinary
}

#check() {
#  cd "$_magic/docker"
#  # Will be added upstream soon
#  ./hack/make.sh dyntest
#}

package() {
  cd docker
  install -Dm755 "bundles/$pkgver/dynbinary/docker-$pkgver" "$pkgdir/usr/bin/docker"
  install -Dm755 "bundles/$pkgver/dynbinary/dockerinit-$pkgver" "$pkgdir/usr/lib/docker/dockerinit"
  # completion
  install -Dm644 "contrib/completion/bash/docker" "$pkgdir/usr/share/bash-completion/completions/docker"
  install -Dm644 "contrib/completion/zsh/_docker" "$pkgdir/usr/share/zsh/site-functions/_docker"
  # systemd
  install -Dm644 "contrib/init/systemd/docker.service" "$pkgdir/usr/lib/systemd/system/docker.service"
}