PKGBUILDs/core/openssl-cryptodev/PKGBUILD

# $Id$
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - use linux-armv4 target for our architectures
#  - cryptodev-enabled version
#
#	moonman <moonman [dot] ca [at] gmail [dot] com>
#  - get cryptodev.h from cryptodev tarball instead of the kernel headers
#  - patches from cryptodev developers for openssl

buildarch=6

pkgname=openssl-cryptodev
_pkgname=openssl
_ver=1.0.2a
# use a pacman compatible version scheme
pkgver=${_ver/[a-z]/.${_ver//[0-9.]/}}
#pkgver=$_ver
pkgrel=2
pkgdesc='The Open Source toolkit for Secure Sockets Layer and Transport Layer Security'
arch=('arm' 'armv7h')
url='https://www.openssl.org'
license=('custom:BSD')
depends=('perl')
optdepends=('ca-certificates')
options=('!makeflags')
backup=('etc/ssl/openssl.cnf')
conflicts=('openssl')
provides=("openssl=${pkgver}")
_cryptover=1.6


source=("https://www.openssl.org/source/${_pkgname}-${_ver}.tar.gz"
        'no-rpath.patch'
        'ca-dir.patch'
        "http://download.gna.org/cryptodev-linux/cryptodev-linux-${_cryptover}.tar.gz"
        'fix_sig-gen_and_allow_copy_evp_contexts.patch')

md5sums=('a06c547dac9044161a477211049f60ef'
         'dc78d3d06baffc16217519242ce92478'
         '3bf51be3a1bbd262be46dc619f92aa90'
         'eade38998313c25fd7934719cdf8a2ea'
         '91c72fe6b89e3134bc61cfb4311bf348')
validpgpkeys=('8657ABB260F056B1E5190839D9C4D26D0E604491')

prepare() {
        cd $srcdir/${_pkgname}-$_ver

        # remove rpath: http://bugs.archlinux.org/task/14367
        patch -p0 -i $srcdir/no-rpath.patch
        # set ca dir to /etc/ssl by default
        patch -p0 -i $srcdir/ca-dir.patch

        msg2 "Patch eng_cryptodev.c"
        patch -p1 -i $srcdir/fix_sig-gen_and_allow_copy_evp_contexts.patch

        # Copy the header file
        cp -u ${srcdir}/cryptodev-linux-${_cryptover}/crypto/cryptodev.h ${srcdir}/openssl-${_ver}/crypto/

}

build() {
	cd $srcdir/${_pkgname}-$_ver

	if [ "${CARCH}" == 'x86_64' ]; then
		openssltarget='linux-x86_64'
	elif [ "${CARCH}" == 'i686' ]; then
		openssltarget='linux-elf'
	elif [ "${CARCH}" == 'arm' -o "${CARCH}" == 'armv7h' ]; then
		openssltarget='linux-armv4'
	fi

	# mark stack as non-executable: http://bugs.archlinux.org/task/12434
	./Configure --prefix=/usr --openssldir=/etc/ssl --libdir=lib \
		-DHAVE_CRYPTODEV -DHASH_MAX_LEN=64 \
		shared threads zlib \
		"${openssltarget}" \
		"-Wa,--noexecstack ${CPPFLAGS} ${CFLAGS} ${LDFLAGS}"

	make depend
	make
}

check() {
	cd $srcdir/$_pkgname-$_ver
	# the test fails due to missing write permissions in /etc/ssl
	# revert this patch for make test
	patch -p0 -R -i $srcdir/ca-dir.patch
	make test
	patch -p0 -i $srcdir/ca-dir.patch
}

package() {
	depends=('cryptodev_friendly')
	cd $srcdir/$_pkgname-$_ver
	make INSTALL_PREFIX=$pkgdir MANDIR=/usr/share/man MANSUFFIX=ssl install
	install -D -m644 LICENSE $pkgdir/usr/share/licenses/$_pkgname/LICENSE
}