PKGBUILDs/community/simutrans/PKGBUILD

# $Id$
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Gilles Gagniard <gilles@gagniard.org>
# Contributor: JD Steffen <jd at steffennet dot org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - get rid of a bad gcc flag in Makefile

pkgname=simutrans
pkgver=120.0
_pkgver=120-0
pkgrel=1
pkgdesc="An open source transportation simulation game"
arch=('i686' 'x86_64')
url="http://simutrans.com/"
license=('PerlArtistic')
depends=('gcc-libs' 'zlib' 'sdl_mixer' 'bzip2' 'simutrans-pak64')
makedepends=('imagemagick')
optdepends=('timidity++: play MIDI music')
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-src-$_pkgver.zip
        http://downloads.sourceforge.net/$pkgname/simulinux-$_pkgver.zip
        settings-folder.patch
        path-for-game-data.patch
        config.patch
        simutrans.desktop)
md5sums=('42d804e3a6ac78460584903ce9b4eeb1'
         'fdc58aee51a79d2a67219acff0cd5b12'
         'c87d9a9910bc371df5d50f7f1ec298bb'
         'e716340d372af264ca05510facfe5d2c'
         '4a2d707ad2fc0abf42e8d75c0a3dcc8b'
         'f41f7a08ad517ef2b60412859eb49963')

prepare() {
  cd "$srcdir"

  cp config.template config.default
  patch -Np0 -i "$srcdir/settings-folder.patch"
  patch -Np1 -i "$srcdir/path-for-game-data.patch"
  patch -Np0 -i "$srcdir/config.patch"

  sed -i 's/-minline-all-stringops/-O3/' Makefile
}

build() {
  cd "$srcdir"
  convert simutrans.ico -alpha on simutrans.png
  make
}

package() {
  cd "$srcdir"

  #binary
  install -Dm755 build/default/sim "$pkgdir/usr/bin/simutrans"

  #data
  mkdir -p "$pkgdir/usr/share/games/$pkgname"
  cp -r "$pkgname"/{config,font,music,script,text,themes} "$pkgdir/usr/share/games/$pkgname"

  #desktop file and icon
  install -Dm644 simutrans.png "$pkgdir/usr/share/pixmaps/simutrans.png"
  install -Dm644 simutrans.desktop "$pkgdir/usr/share/applications/simutrans.desktop"
}