PKGBUILDs/community/gmic/PKGBUILD

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: farid <farid at archlinuc-br.org>
# Contributor: Archie <Mymaud@gmail.com>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - remove -mtune=generic from makefile, replace with our CFLAGS

highmem=1

pkgbase=gmic
pkgname=(gmic zart gimp-plugin-gmic krita-plugin-gmic)
pkgver=2.2.1
_commit=26c271d8a721447f24f118c9d0236a02118d0009
pkgrel=2
arch=(x86_64)
url="http://gmic.eu/"
license=(custom:CeCILL)
makedepends=(gimp qt5-base fftw openexr opencv git hdf5 gtkglext)
source=("https://gmic.eu/files/source/gmic_$pkgver.tar.gz"
        git://github.com/dtschump/gmic-community.git#commit=$_commit
	gmic-qt-v.$pkgver.tar.gz::"https://github.com/c-koi/gmic-qt/archive/v.$pkgver.tar.gz")
sha256sums=('3c05754568127d20d0ab3b50e49e00d3c89b26078a15725d0bfb8b1ed50f4c45'
            'SKIP'
            'ab2db76d92cd476e9e45fd226f9ebca86819a3d17d740ad5172e094e072f26c0')

prepare() {
  mv gmic-$pkgver gmic
  mv gmic-community/zart zart
  mv gmic-qt-v.$pkgver gmic-qt

  sed -e 's|/etc/bash_completion.d|/usr/share/bash-completion/completions|g' -i gmic/src/Makefile
  sed -e 's|-Ofast|-O2 -fno-fast-math|g' -i gmic-qt/gmic_qt.pro

  sed -i "s|-mtune=generic|${CFLAGS}|" gmic/src/Makefile
}

build() {
  cd gmic
  make -C src all WGET=/bin/true -j1
}

package_gmic() {
  pkgdesc="GREYC's Magic Image Converter: image processing framework"
  depends=(opencv fftw curl)
  optdepends=('qt5-base: for the Qt UI')

  cd gmic/src
  make DESTDIR="$pkgdir" install
  install -Dm644 ../COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  rm -rf "$pkgdir"/usr/{bin/zart,lib/gimp,share/zart,bin/gmic_krita_qt}
}

package_zart() {
  pkgdesc="A GUI for G'MIC real-time manipulations on the output of a webcam"
  depends=(opencv fftw qt5-base)

  install -Dm755 zart/zart -t "$pkgdir"/usr/bin
  install -Dm644 zart/Licence_CeCILL_V2-en.html -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_gimp-plugin-gmic() {
  pkgdesc="Gimp plugin for the G'MIC image processing framework"
  depends=(gimp fftw qt5-base curl)

  install -Dm755 gmic-qt/gmic_gimp_qt "$pkgdir"/usr/lib/gimp/2.0/plug-ins/gmic_gimp
  install -Dm644 gmic-qt/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_krita-plugin-gmic() {
  pkgdesc="Krita plugin for the G'MIC image processing framework"
  depends=(krita)

  cd gmic-qt
  install -Dm755 gmic_krita_qt -t "$pkgdir"/usr/bin/
}