PKGBUILDs/core/initscripts/PKGBUILD

# $Id: PKGBUILD 165801 2012-08-30 16:58:57Z tomegun $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Thomas Bächler <thomas@archlinux.org>
# Contributor: Aaron Griffin <aaron@archlinux.org>

pkgname=initscripts
pkgver=2012.08.3
pkgrel=2
pkgdesc="System initialization/bootup scripts"
arch=('any')
url="http://www.archlinux.org"
license=('GPL2')
groups=('base')
provides=('initscripts-systemd')
conflicts=('initscripts-systemd')
replaces=('initscripts-systemd')
backup=(etc/inittab etc/rc.conf etc/rc.local etc/rc.local.shutdown)
depends=('glibc' 'bash' 'coreutils' 'systemd-tools' 'iproute2' 'ncurses' 'findutils' 'sysvinit')
optdepends=('dhcpcd: DHCP network configuration'
            'bridge-utils: Legacy network bridging support'
            'net-tools: Legacy network support'
            'wireless_tools: Legacy wireless networking')
makedepends=(asciidoc)
install=initscripts.install
source=("ftp://ftp.archlinux.org/other/initscripts/${pkgname}-${pkgver}.tar.xz"
        'alarm.patch'
        'rc.conf')
md5sums=('b5e8de40bf798637cb1634a1555d0f1f'
         'e7ec1f2d469258b91bbda84284d37c4c'
         'c618e099f522f861e08a475f8960a6c2')

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  patch -p1 -i "${srcdir}/alarm.patch"
  cp "${srcdir}/rc.conf" .
  [ "${CARCH}" == "arm" ]    && sed -i 's/@TTY@/ttyS0/' inittab
  [ "${CARCH}" == "armv6h" ] && sed -i 's/@TTY@/ttyS0/' inittab
  [ "${CARCH}" == "armv7h" ] && sed -i 's/@TTY@/ttyO2/' inittab

  make DESTDIR=${pkgdir} install

  # moved to filesystem
  rm -rf ${pkgdir}/etc/profile.d
  rm ${pkgdir}/usr/share/man/man7/archlinux.7
}