PKGBUILDs/community/tachyon/PKGBUILD

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Rémy Oudompheng <remy@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - set ARM architectures to use linux-thr profile, AArch64 to linux-64-thr
#  - sed to remove -m32 and -m64 from CFLAGS

pkgname=tachyon
pkgver=0.98.9
pkgrel=6
pkgdesc="Multithreaded ray tracing software"
arch=(x86_64)
url="http://jedi.ks.uiuc.edu/~johns/raytracer/"
license=(BSD)
depends=(libjpeg-turbo libpng)
makedepends=()
#source=("http://jedi.ks.uiuc.edu/~johns/raytracer/files/$pkgver/$pkgname-$pkgver.tar.gz" 'enable-jpeg-png.patch')
source=("https://mirrors.mit.edu/sage/spkg/upstream/tachyon/tachyon-$pkgver.tar.bz2" enable-jpeg-png.patch tachyon-system-cflags.patch)
sha256sums=('e8888a410610e2726dca32f40f31ff34a83cb474b41e5a1e0ac8bbb175e1a466'
            'ecd6ab6274879e0f971e2eba17871fffe2e24dcc9a332013a0b100ee4857cc2c'
            '34f703af96afe117c851a5825b7fd6b71211c09e4a8c3b836d012d250bb6918f')

case "$CARCH" in
  arm*) _target=linux-thr ;;
  "aarch64") _target=linux-64-thr ;;
  "i686") _target=linux-thr ;;
  "x86_64") _target=linux-64-thr ;;
esac

prepare(){
  cd $pkgname-$pkgver
# enable JPEG and PNG support
  patch -p0 -i ../enable-jpeg-png.patch
# use system build flags
  patch -p1 -i ../tachyon-system-cflags.patch
  sed -e 's|${CC} ${CFLAGS}|${CC} ${CFLAGS} ${LDFLAGS}|g' -i unix/Makefile

  # remove -m32 and -m64 for ARM
  sed -i 's/-m32//g' unix/Make-arch
  sed -i 's/-m64//g' unix/Make-arch
}

build() {
  cd $pkgname-$pkgver/unix
  make $_target CC="gcc ${CFLAGS} ${LDFLAGS}"
}

package() {
  cd $pkgname-$pkgver/compile/$_target
  install -D -m 755 tachyon $pkgdir/usr/bin/tachyon
  install -D -m 644 libtachyon.a $pkgdir/usr/lib/libtachyon.a

  install -d "$pkgdir"/usr/share/licenses/tachyon
  install "$srcdir"/$pkgname-$pkgver/Copyright "$pkgdir"/usr/share/licenses/tachyon
}