PKGBUILDs/extra/p7zip/PKGBUILD

# $Id$
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Thayer Williams <thayer@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Contributor: TuxSpirit<tuxspirit@archlinux.fr>  2007/11/17 21:22:36 UTC
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - use makefile.linux_any_cpu

pkgname=p7zip
pkgver=16.02
pkgrel=4
pkgdesc="Command-line file archiver with high compression ratio"
arch=('x86_64')
url="http://p7zip.sourceforge.net/"
license=('LGPL' 'custom:unRAR')
depends=('gcc-libs' 'sh')
makedepends_i686=('nasm')
makedepends_x86_64=('yasm')
install=$pkgname.install
source=(https://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/${pkgname}_${pkgver}_src_all.tar.bz2
        CVE-2016-9296.patch
        CVE-2017-17969.patch
        CVE-2018-5996.patch)
sha256sums=('5eb20ac0e2944f6cb9c2d51dd6c4518941c185347d4089ea89087ffdd6e2341f'
            'f9bcbf21d4aa8938861a6cba992df13dec19538286e9ed747ccec6d9a4e8f983'
            '0027f47eb8633244ac0177c1bb4ed50afa64ab757b34379a4b64ac923b9385b0'
            '9c92b9060fb0ecc3e754e6440d7773d04bc324d0f998ebcebc263264e5a520df')

prepare() {
  cd "$srcdir/${pkgname}_$pkgver"

  # https://sourceforge.net/p/p7zip/bugs/185/
  patch -Np1 -i ../CVE-2016-9296.patch

  # https://sourceforge.net/p/p7zip/bugs/204/
  patch -Np1 -i ../CVE-2017-17969.patch

  # Patch from Debian which hopefully fixes CVE-2018-5996
  patch -Np1 -i ../CVE-2018-5996.patch

  cp makefile.linux_any_cpu_gcc_4.X makefile.machine
}

build() {
  cd "$srcdir/${pkgname}_$pkgver"
  make all3 OPTFLAGS="$CFLAGS"
}

package() {
  cd "$srcdir/${pkgname}_$pkgver"

  make install \
    DEST_DIR="$pkgdir" \
    DEST_HOME=/usr \
    DEST_MAN=/usr/share/man

  # Remove documentation for the GUI file manager
  rm -r "$pkgdir/usr/share/doc/p7zip/DOC/MANUAL/fm"

  install -d "${pkgdir}"/usr/share/licenses/p7zip
  ln -s -t "$pkgdir/usr/share/licenses/p7zip/" \
    /usr/share/doc/p7zip/DOC/License.txt \
    /usr/share/doc/p7zip/DOC/unRarLicense.txt
}

# vim:set ts=2 sw=2 et: