PKGBUILDs/extra/bullet/PKGBUILD

# Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - -DBUILD_BULLET2_DEMOS=OFF, -DBUILD_UNIT_TESTS=OFF, -DBUILD_EXTRAS=OFF

pkgbase=bullet
pkgname=('bullet' 'bullet-docs' 'python-pybullet')
pkgver=3.07
pkgrel=1
pkgdesc="A 3D Collision Detection and Rigid Body Dynamics Library for games and animation"
arch=('x86_64')
url="http://www.bulletphysics.com/Bullet/"
license=('custom:zlib')
makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'glu' 'python' 'python-numpy' 'python-setuptools' 'ninja')
source=("$pkgname-$pkgver.tar.gz::https://github.com/bulletphysics/bullet3/archive/${pkgver}.tar.gz"
        https://github.com/bulletphysics/bullet3/commit/e32fc59c88a3908876949c6f2665e8d091d987fa.patch
        bullet3_examplebrowser.sh)
sha512sums=('31fc7cb4ed8b939abc9eeb0a8f6fff3a454ea4ebcffd797fd35a2320fe3ab222fcd315569809ea148d0efff47267f5eec9f4bf7aaf07730a06aa9babd2abc9a6'
            'd3a2c2698d988c0d3972060b411029a91b4e37149e1fa120e2cb15fd25eb06bb4094745bdd682427cb3b6128c88fa7d42f0cf78064e7da36a034a80f327b7c33'
            '8741ad94b6c46c226d89aebc8ab06d8a11bac3c04d3f0a2bf7a7524792a3375aa7bf7d295410b16fbeb4c348a31057b4570acdebe9bbaea251f44daca8d9fe81')

prepare() {
  cd bullet3-${pkgver}
  patch -Np1 -i "${srcdir}"/e32fc59c88a3908876949c6f2665e8d091d987fa.patch
}

build() {
  cd bullet3-${pkgver}

  cmake . \
      -Bbuild \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DBUILD_SHARED_LIBS=1 \
      -DINSTALL_LIBS=1 \
      -DINSTALL_EXTRA_LIBS=1 \
      -DBUILD_PYBULLET=ON \
      -DBUILD_PYBULLET_NUMPY=ON \
      -DBUILD_OPENGL3_DEMOS=ON \
      -DBUILD_BULLET2_DEMOS=OFF \
      -DBUILD_UNIT_TESTS=OFF \
      -DBUILD_EXTRAS=OFF \
      -DCMAKE_BUILD_TYPE=Release

  ninja -C build

  python setup.py build
  doxygen
}

package_bullet() {
  optdepends=('glu: for the example browser'
              'python: python bindings'
              'python-numpy: python bindings'
              'bullet-docs: documentation')

  cd bullet3-${pkgver}

  DESTDIR="${pkgdir}" ninja -C build install

  cd build

  #install -Dm755 examples/pybullet/pybullet.so.${pkgver} "${pkgdir}"/usr/lib/libpybullet.so.${pkgver}
  #install -Dm755 examples/ExampleBrowser/libBulletExampleBrowserLib.so.${pkgver} "${pkgdir}"/usr/lib/libBulletExampleBrowserLib.so.${pkgver}
  #install -Dm755 examples/OpenGLWindow/libOpenGLWindow.so "${pkgdir}"/usr/lib/libOpenGLWindow.so
  #install -Dm755 examples/ThirdPartyLibs/Gwen/libgwen.so "${pkgdir}"/usr/lib/libgwen.so
  #install -Dm755 examples/ThirdPartyLibs/BussIK/libBussIK.so "${pkgdir}"/usr/lib/libBussIK.so
  #install -Dm755 "${srcdir}"/bullet3_examplebrowser.sh "${pkgdir}"/usr/bin/bullet3_examplebrowser
  #install -Dm755 examples/ExampleBrowser/App_ExampleBrowser "${pkgdir}"/opt/bullet/App_ExampleBrowser
  #cp -r data "${pkgdir}"/opt/bullet/

  install -Dm644 ../LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgbase}/LICENSE
}

package_python-pybullet() {
  pkgdesc="Bullet Python bindings"
  depends+=('bullet' 'gcc-libs')

  cd bullet3-${pkgver}

  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build

  install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_bullet-docs() {
  pkgdesc="Documentation for bullet"

  cd bullet3-${pkgver}

  # install docs
  install -Dm644 docs/GPU_rigidbody_using_OpenCL.pdf "${pkgdir}"/usr/share/doc/bullet/GPU_rigidbody_using_OpenCL.pdf
  install -Dm644 docs/Bullet_User_Manual.pdf "${pkgdir}"/usr/share/doc/bullet/Bullet_User_Manual.pdf
  install -Dm644 docs/BulletQuickstart.pdf "${pkgdir}"/usr/share/doc/bullet/BulletQuickstart.pdf
  cp -r html "${pkgdir}"/usr/share/doc/bullet/html
}
# vim: sw=2 ts=2 et: