Merge pull request #379 from gtmanfred/master

add compton-git

aur/compton-git/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: OK100 <ok100@lavabit.com>
+# Previous Maintainer: Valère Monseur <valere dot monseur at ymail dot com>
+
+pkgname=compton-git
+pkgver=20121204
+pkgrel=1
+pkgdesc="X Compositor (a fork of xcompmgr-dana)"
+arch=(i686 x86_64)
+url="https://github.com/chjj/compton"
+license=('MIT')
+depends=('libx11' 'libxcomposite' 'libxdamage' 'libxfixes' 'libxext' 'libxrender' 'xproto' 'bash' 'xorg-xprop' 'xorg-xwininfo' 'pcre' 'libconfig' 'mesa' 'libxrandr')
+makedepends=('git' 'make' 'pkg-config' 'asciidoc')
+
+_gitroot="git://github.com/chjj/compton.git"
+_gitname="compton"
+
+build() {
+  msg "Connecting to GIT server...."
+
+  if [ -d $_gitname ] ; then
+    cd $_gitname && git pull origin
+    msg "The local files are updated."
+  else
+    git clone $_gitroot $_gitname
+  fi
+
+  msg "GIT checkout done or server timeout"
+  msg "Starting make..."
+
+  rm -rf "$srcdir/$_gitname-build"
+  git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"
+
+  cd "$srcdir/$_gitname-build"
+  make PREFIX=/usr
+  make docs
+}
+
+package() {
+  cd $_gitname-build
+
+  make PREFIX="$pkgdir/usr" install
+
+  # install license
+  install -D -m644 "LICENSE" "$pkgdir/usr/share/licenses/$_gitname/LICENSE"
+
+  # example conf
+  install -D -m644 "compton.sample.conf" "$pkgdir/etc/xdg/compton.conf.example"
+}