added extra/qt6-tools

extra/qt6-tools/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Antonio Rojas <arojas@archlinux.org>
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+
+# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
+#  - explicitly link v5/v6 with libatomic
+
+pkgname=qt6-tools
+_qtver=6.0.0
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='A cross-platform application and UI framework (Development Tools, QtHelp)'
+depends=(qt6-base)
+makedepends=(cmake qt6-declarative vulkan-headers clang llvm)
+optdepends=('clang: for qdoc and lupdate')
+groups=(qt6)
+_pkgfn="${pkgname/6-/}-everywhere-src-${_qtver}"
+source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz")
+sha256sums=('b6dc559db447bf394d09dfb238d5c09108f834139a183888179e855c6566bfae')
+
+build() {
+  [[ $CARCH == "arm" || $CARCH == "armv6h" ]] && echo "target_link_libraries(qtdiag PRIVATE atomic)" >> ${_pkgfn}/src/qtdiag/CMakeLists.txt
+  cmake -B build -S $_pkgfn
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+# Symlinks for backwards compatibility
+  mkdir "$pkgdir"/usr/bin
+  for b in "${pkgdir}"/usr/lib/qt6/bin/*; do
+    ln -rs "$pkgdir"/usr/lib/qt6/bin/$(basename $b) "$pkgdir"/usr/bin/$(basename $b)-qt6
+  done
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+}