mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
54 lines
2.1 KiB
Bash
54 lines
2.1 KiB
Bash
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
# Contributor: Ronald van Haren <ronald.archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - remove makedepend on vc
|
|
|
|
pkgname=calligra
|
|
pkgdesc="A set of applications for productivity and creative usage"
|
|
pkgver=3.2.1
|
|
pkgrel=12
|
|
arch=(x86_64)
|
|
url='https://www.calligra-suite.org/'
|
|
license=(FDL1.2 GPL2 LGPL)
|
|
depends=(kcmutils knotifyconfig kross kactivities kdiagram libspnav kdelibs4support
|
|
gsl openexr kcontacts qca poppler-qt5 libodfgen khtml cauchy)
|
|
makedepends=(extra-cmake-modules kdoctools kdesignerplugin kinit libwpg okular eigen marble-common
|
|
boost pstoedit libvisio libetonyek libwps libgit2 kcalendarcore akonadi)
|
|
optdepends=('libwpg: Corel WordPerfect Graphics image importer'
|
|
'libwps: Microsoft Works file word processor format import'
|
|
'libvisio: Microsoft Visio import filter'
|
|
'libetonyek: Apple Keynote import filter'
|
|
'pstoedit: EPS to SVG filter'
|
|
'poppler: PDF to SVG filter'
|
|
'libgit2: Calligra Gemini git plugin'
|
|
'kirigami2: for Calligra Gemini'
|
|
'qt5-quickcontrols: for Calligra Gemini'
|
|
'qt5-webengine: for Calligra Gemini')
|
|
source=(https://download.kde.org/stable/$pkgname/$pkgver/$pkgname-$pkgver.tar.xz{,.sig}
|
|
calligra-openexr3.patch)
|
|
sha256sums=('b1f8a6eb8208543a2f908caa83d089075fcd1e530d00e19f5362b2f9cc371147'
|
|
'SKIP'
|
|
'0dec106deff4cff342021da4ca4e9759f0bbe5707ea2d4ee8536eaf863409cec')
|
|
validpgpkeys=(05D00A8B73A686789E0A156858B9596C722EA3BD # Boudewijn Rempt <foundation@krita.org>
|
|
42A60D06F449E895F40F09C01638B8A616108B8A) # Dag Andersen <danders@get2net.dk>
|
|
|
|
prepare() {
|
|
patch -d $pkgname-$pkgver -p1 < calligra-openexr3.patch # Fix build with OpenEXR 3
|
|
}
|
|
|
|
build() {
|
|
cmake -B build -S $pkgname-$pkgver \
|
|
-DBUILD_TESTING=OFF
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
# Remove utterly broken thumbnailers
|
|
rm "$pkgdir"/usr/lib/qt/plugins/calligra*thumbnail.so
|
|
}
|