mirror of
https://github.com/archlinuxarm/PKGBUILDs.git
synced 2024-09-19 22:08:32 +00:00
72 lines
2.4 KiB
Bash
72 lines
2.4 KiB
Bash
# $Id: PKGBUILD 240297 2015-06-03 10:22:03Z fyan $
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
|
|
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
|
|
# - patch to link with libatomic on v5/v6
|
|
# - disable jit on v5/v6
|
|
|
|
highmem=1
|
|
|
|
pkgname=qt5-webkit
|
|
_qtver=5.212.0-alpha2
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=4
|
|
arch=(i686 x86_64)
|
|
url='http://qt-project.org/'
|
|
license=(GPL3 LGPL3 FDL custom)
|
|
pkgdesc='Classes for a WebKit2 based implementation and a new QML API'
|
|
depends=(qt5-location qt5-sensors qt5-webchannel libwebp libxslt libxcomposite gst-plugins-base hyphen)
|
|
makedepends=(cmake ruby gperf python2 qt5-doc qt5-tools)
|
|
optdepends=('gst-plugins-good: Webm codec support')
|
|
conflicts=(qt5-webkit-ng qt5-webkit-og)
|
|
replaces=(qt5-webkit-ng qt5-webkit-og)
|
|
groups=(qt qt5)
|
|
_pkgfqn="${pkgname/5-/}-opensource-src-${_qtver}"
|
|
source=("https://github.com/annulen/webkit/releases/download/qtwebkit-$_qtver/qtwebkit-$_qtver.tar.xz"
|
|
qt5-webkit-gcc7.patch
|
|
atomic.patch)
|
|
sha256sums=('f8f901de567e11fc5659402b6b827eac75505ff9c5072d8e919aa306003f8f8a'
|
|
'f108833562d766d4c086026f9202b2ebc8c19e97fddedce952afed78df3c0720'
|
|
'23fbd785daf116c71b3ce87d40860f0a6c56ab1065ee98ec41634626ca961129')
|
|
|
|
prepare() {
|
|
mkdir -p build
|
|
|
|
# Fix crashes with GCC7 https://bugs.webkit.org/show_bug.cgi?id=173407
|
|
cd qtwebkit-$_qtver
|
|
patch -p1 -i ../qt5-webkit-gcc7.patch
|
|
if [[ $CARCH == "arm" || $CARCH == "armv6h" ]]; then
|
|
patch -p0 -i ../atomic.patch
|
|
fi
|
|
}
|
|
|
|
build() {
|
|
cd build
|
|
|
|
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
|
|
|
|
cmake ../qtwebkit-$_qtver \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DPORT=Qt \
|
|
-DENABLE_TOOLS=OFF \
|
|
$CONFIG
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd build
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
install -d "$pkgdir"/usr/share/licenses
|
|
ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
|
|
|
|
# Fix pkgconfig files
|
|
sed -e 's|qt/Qt5WebKit|qt/QtWebKit|' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKit.pc
|
|
sed -e 's|qt/Qt5WebKitWidgets|qt/QtWebKitWidgets|' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKitWidgets.pc
|
|
sed -e '/Name/a Description: Qt WebKit module' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKit.pc
|
|
sed -e '/Name/a Description: Qt WebKitWidgets module' -i "$pkgdir"/usr/lib/pkgconfig/Qt5WebKitWidgets.pc
|
|
}
|