PKGBUILDs/community/supercollider/PKGBUILD

# Maintainer: Brett Cornwall <ainola@archlinux.org>
# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>
# Contributor: osc <farid at archlinux-br.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - added recommended cmake defines (last two lines)

_name=SuperCollider
pkgname=supercollider
pkgver=3.12.2
pkgrel=1
pkgdesc="Platform for audio synthesis and algorithmic composition"
arch=(x86_64)
url="https://supercollider.github.io"
license=(GPL3)
groups=(pro-audio)
depends=(gcc-libs glibc  libx11 qt5-base qt5-svg qt5-webengine qt5-websockets)
makedepends=(abletonlink alsa-lib avahi boost cmake emacs fftw libsndfile
qt5-tools readline systemd-libs yaml-cpp)
checkdepends=(xorg-server-xvfb)
optdepends=('emacs: emacs interface'
            'gedit: gedit interface'
            'sc3-plugins: additional extension plugins for scsynth')
provides=(libscsynth.so "sclang=${pkgver}" "scsynth=${pkgver}")
source=(
    "https://github.com/${pkgname}/${pkgname}/releases/download/Version-${pkgver}/${_name}-${pkgver}-Source.tar.bz2"{,.asc}
)
install="${pkgname}.install"
sha512sums=('ad2466047353b65879f2acd9ba6b6f429010af08ef3f1150adebb93927244f4337aeb09d5aa6cc4cd26b091bc101488eebf822d21c177de55f0f8f7c2a31eb7c'
            'SKIP')
b2sums=('27ffb7ad1dc4be637e166789116a5f6f09a995a374003c1f5f2a29ccaacaaf6778fd52ee32de17a6eadc16472d6d333a483b947432d9f1229045139b63f66fcb'
        'SKIP')
validpgpkeys=('2E1C4FC2F6BB58FA157B21B8064B501EB7405F04') # Marcin Pączkowski (dyfer)


build() {
  export CFLAGS+=" -DNDEBUG"
  export CXXFLAGS+=" -DNDEBUG"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE='None' \
        -DBoost_NO_BOOST_CMAKE=ON \
        -DLIBSCSYNTH=ON \
        -DFORTIFY=ON \
        -DSYSTEM_ABLETON_LINK=ON \
        -DSYSTEM_BOOST=ON \
        -DSYSTEM_YAMLCPP=ON \
        -DSC_VIM=OFF \
        -Wno-dev \
        -B build \
        -DSSE=OFF -DSSE2=OFF -DSUPERNOVA=OFF -DNOVA_SIMD=ON -DNATIVE=OFF \
        -DCMAKE_C_FLAGS="${CFLAGS}" \
        -S "${_name}-${pkgver}-Source"
  make VERBOSE=1 -C build
}

check() {
  xvfb-run make test ARGS="-VV -d -j1" -C build
}

package() {
  depends+=(libasound.so libavahi-common.so libavahi-client.so
  libboost_filesystem.so libboost_program_options.so libboost_regex.so
  libboost_thread.so libfftw3f.so libjack.so libsndfile.so libreadline.so
  libudev.so libyaml-cpp.so)

  make DESTDIR="${pkgdir}" install -C build
  install -vDm 644 "${_name}-${pkgver}-Source/"{AUTHORS,{CHANGELOG,README,README_LINUX}.md} -t "${pkgdir}/usr/share/doc/${pkgname}/"
}