PKGBUILDs/community/curaengine/PKGBUILD

# Maintainer: Jelle van der Waa <jelle@archlinux.org>
# Contributor: Grey Christoforo <first name [at] last name [dot] net>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - -DBUILD_TESTS=OFF

pkgname=curaengine
pkgver=4.13.0
pkgrel=1
pkgdesc="Engine for processing 3D models into 3D printing instruction for Ultimaker and other GCode based 3D printers."
url="https://github.com/Ultimaker/CuraEngine"
arch=('x86_64')
license=('AGPL')
depends=('arcus' 'polyclipping')
checkdepends=('cppunit')
makedepends=('cmake' 'git' 'gtest' 'rapidjson')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Ultimaker/${pkgname}/archive/${pkgver}.tar.gz")
sha512sums=('3d52c67c0968f6caffd9e0b86743f70916705e6f2896466e69a179ce97b6d35f7af33b056e9375abaa445a00438d25e5f782a7e2a92c0805cec0c0527a25426c')


build() {
  cd CuraEngine-${pkgver}
  mkdir -p build
  cd build
    
   cmake .. \
     -DCMAKE_INSTALL_PREFIX=/usr \
     -DBUILD_TESTS=OFF \
     -DUSE_SYSTEM_LIBS=ON \
     -DCMAKE_BUILD_TYPE='None'

  make
}

check() {
  cd CuraEngine-${pkgver}/build
  # This test fails in when instance->readMeshGroupMessage(mesh_message) is
  # called in the buildchroot but not outside
  ARGS="-E ArcusCommunicationPrivateTest" make test
}

package() {
  cd CuraEngine-${pkgver}/build
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: