PKGBUILDs/extra/libvpx/PKGBUILD

# $Id: PKGBUILD 149273 2012-02-06 17:33:27Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to fix building
#  - disable neon and neon-asm

pkgname=libvpx
pkgver=1.5.0
pkgrel=4
pkgdesc='VP8 and VP9 codec'
arch=('i686' 'x86_64')
url='http://www.webmproject.org/'
license=('BSD')
depends=('glibc' 'gcc-libs')
makedepends=('yasm' 'git')
provides=('libvpx.so')
source=($pkgname-$pkgver.tar.gz::https://github.com/webmproject/libvpx/archive/v$pkgver.tar.gz
        0001-Fix-for-issue-1114-compile-error.patch
        fix-armhf-link.patch)
md5sums=('0c662bc7525afe281badb3175140d35c'
         'a03e318d5d92270ed826b55d6d9dc828'
         'a2d92d01ecc336fe81682daa8a7fdafa')

prepare() {
  cd $pkgname-$pkgver

  # https://bugs.chromium.org/p/webm/issues/detail?id=1114
  patch -Np1 -i ../0001-Fix-for-issue-1114-compile-error.patch

  patch -p1 -i ../fix-armhf-link.patch
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr \
    --enable-vp8 \
    --enable-vp9 \
    --enable-vp9-highbitdepth \
    --enable-runtime-cpu-detect \
    --enable-shared \
    --enable-postproc \
    --enable-pic \
    --enable-experimental --enable-spatial-svc \
    --disable-install-docs \
    --disable-install-srcs \
    --disable-neon --disable-neon-asm
  make
}

package() {
  cd $pkgname-$pkgver
  make DIST_DIR="$pkgdir/usr" install
  install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}