PKGBUILDs/extra/digikam/PKGBUILD

# $Id$
# Maintainer: Ronald van Haren <ronald@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>

# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - patch to enable/disable OpenGL via a switch
#  - cmake with -DENABLE_OPENGL=OFF

pkgbase=digikam
pkgname=('digikam' 'kipi-plugins')
_pkgver=5.7.0
pkgver=${_pkgver//-/_} # for beta versions
pkgrel=3
pkgdesc="An advanced digital photo management application"
arch=('x86_64')
license=('GPL')
url="http://www.digikam.org/"
makedepends=('extra-cmake-modules' 'libkipi' 'libksane' 'liblqr' 'opencv' 'boost'
             'doxygen' 'lensfun' 'eigen' 'kdoctools' 'marble-common' 'kdesignerplugin'
             'kfilemetadata' 'akonadi-contacts' 'qtav' 'threadweaver' 'kcalcore'
             'knotifyconfig' 'libmediawiki' 'libkvkontakte')
source=("http://download.kde.org/stable/${pkgname}/${pkgname}-${_pkgver}.tar.xz"
        digikam-kcalcore-17.12.patch
        digikam-qt-5.9.3.patch::"https://cgit.kde.org/digikam.git/patch/?id=855ba5b7"
        0001-optionally-enable-OpenGL.patch)
sha256sums=('3605ffb5b6e8fbd6b725e5075f74f505d7edee7531789c2882d11df2d20150f5'
            '61648bdeb88dcb94d2896b9d9211c6a6b50a39a143701e04465aa040a60053c0'
            '03822e596321028d0971ec82351337dad76abeda93c9cef3b1d2a31807e02661'
            'f6f234f430f02e058e12e48577f9d8441959e84b42f4e50d733706be8b214bf5')

prepare() {
  mkdir -p build

# sv docs fail to build
  sed -e '/sv/d' -i $pkgname-$pkgver/doc-translated/CMakeLists.txt
# fix conflicts with libkvkontakte
  rm $pkgbase-$pkgver/po/*/libkvkontakte.po
# fix build with kcalcore 17.12
  cd $pkgname-$_pkgver/core
  patch -p1 -i "$srcdir"/digikam-kcalcore-17.12.patch
# fix thumbnails with Qt 5.9.3
  patch -p1 -i "$srcdir"/digikam-qt-5.9.3.patch

  # OpenGL switch
  patch -p1 -i ${srcdir}/0001-optionally-enable-OpenGL.patch
}

build() {
  cd build

  cmake ../${pkgname}-${_pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release \
    -DBUILD_TESTING=OFF \
    -DENABLE_KFILEMETADATASUPPORT=ON \
    -DENABLE_MEDIAPLAYER=ON \
    -DENABLE_AKONADICONTACTSUPPORT=ON \
    -DENABLE_MYSQLSUPPORT=ON \
    -DENABLE_OPENCV3=ON \
    -DENABLE_APPSTYLES=ON \
    -DENABLE_OPENGL=OFF
  make
}

package_digikam() {
  pkgdesc="Digital photo management application for KDE"
  depends=('liblqr' 'libkipi' 'lensfun' 'opencv' 'akonadi-contacts'
	'knotifyconfig' 'libksane' 'kfilemetadata' 'qtav' 'marble-common' 'threadweaver' 'kcalcore')
  optdepends=('kipi-plugins: export to various online services'
              'hugin: panorama tool' 'qt5-imageformats: WEBP format support')

  cd build/core
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/doc
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/po
  make DESTDIR="$pkgdir" install

# Provided by kipi-plugins
  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/kipiplugin*.mo
}

package_kipi-plugins() {
  pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam"
  depends=('kio' 'libkipi')
  optdepends=('libmediawiki: MediaWiki Export plugin'
              'libkvkontakte: VKontakte.ru Exporter plugin')

  cd build/extra
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/po
  make DESTDIR="$pkgdir" install

# Provided by digikam
  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
}