PKGBUILDs/alarm/omxplayer-git/PKGBUILD

# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: Huulivoide <gmail.com: jesse.jaara>
# Contributor: Jonathan Hudson <daria.co.uk: jh+arch>

buildarch=4

pkgname=omxplayer-git
pkgver=530.1f1d0cc
pkgrel=1
pkgdesc="omxplayer is a command line media player for the RaspberryPi"
arch=('armv6h' 'armv7h')
url="https://github.com/popcornmix/omxplayer"
license=(GPL2)
depends=('ffmpeg4.4' 'raspberrypi-firmware' 'fbset')
makedepends=('git' 'boost')
optdepends=('ttf-freefont')
provides=(omxplayer)
conflicts=('omxplayer' 'omxplayer-bin')
source=('git+https://github.com/popcornmix/omxplayer'
        '0001-alarm-fixes.patch')
md5sums=('SKIP'
         'f0a3f74ace409cf428536d791aa7b500')

pkgver() {
  cd omxplayer
  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

prepare() {
  cd "${srcdir}/omxplayer"

  git apply ../0001-alarm-fixes.patch
}

build() {
  cd "${srcdir}/omxplayer"

  make
}

package() {
  cd "${srcdir}/omxplayer"

  make DESTDIR="${pkgdir}" install
}